Cara Cepat Mengekspor Semua Folder & Item Outlook di Bagian "Favorit" ke Folder Windows

Jika Anda ingin mengekspor semua folder Outlook serta itemnya di bagian "Favorit", Anda dapat merujuk ke artikel ini. Di sini kami akan menunjukkan cara mencapainya dalam waktu cepat.

Umumnya, folder dan itemnya di Bagian "Favorit" sangat penting dan sering kali dibutuhkan. Oleh karena itu, terkadang, Anda mungkin ingin mengekspornya ke drive lokal. Dengan cara standar, Anda harus membuat folder Windows sesuai folder di "Favorit" dan menyimpan item sebagai file MSG satu per satu di drive lokal. Itu terlalu membosankan. Karenanya, di sini kami akan memaparkan cara yang jauh lebih efisien. Sekarang baca terus untuk mendapatkannya.

Ekspor Semua Folder & Item di Bagian "Favorit" ke Folder Windows

1. Untuk memulai, akses editor VBA di Outlook dengan merujuk ke "Cara Menjalankan Kode VBA di Outlook Anda".
2. Kemudian, salin kode berikut ke dalam modul kosong.

Sub ExportAllFoldersItems_InFavorites_ToWindowsFolder()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFileSystem As Object
    Dim strWindowsFolder As String
    Dim objNavigationPane As Outlook.NavigationPane
    Dim objNavigationModule As Outlook.NavigationModule
    Dim objNavigationGroup As Outlook.NavigationGroup
    Dim objNavigationFolder As Outlook.NavigationFolder
    Dim objFolder As Outlook.Folder
    Dim strFolderPath As String
    Dim objItem As Object
    Dim strFilePath As String
    Dim i As Long
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
     
       'Get "Favorites" section
       Set objNavigationPane = Application.ActiveExplorer.NavigationPane
       Set objNavigationModule = objNavigationPane.Modules.GetNavigationModule(olModuleMail)
       Set objNavigationGroup = objNavigationModule.NavigationGroups.GetDefaultNavigationGroup(olFavoriteFoldersGroup)
 
       'Export the folders and items in "Favorites" section
       For Each objNavigationFolder In objNavigationGroup.NavigationFolders
           Set objFolder = objNavigationFolder.Folder
           strFolderPath = strWindowsFolder & objFolder.Name
           objFileSystem.CreateFolder strFolderPath
 
           For Each objItem In objFolder.Items
               strSubject = objItem.Subject
               strFileName = strSubject & ".msg"
 
               i = 0
               Do Until False
                  strFilePath = strFolderPath & "\" & strFileName
                  If objFileSystem.FileExists(strFilePath) Then
                     i = i + 1
                     strFileName = strSubject & " (" & i & ").msg"
                  Else
                     Exit Do
                  End If
               Loop
 
               objItem.SaveAs strFilePath, olMSG
          Next
       Next
 
       'Open the Windows folder
       Call Shell("explorer.exe " & strWindowsFolder, vbNormalFocus)
    End If
End Sub

3. Kemudian, klik ikon "Jalankan" di bilah alat.
4. Selanjutnya, di kotak dialog pop-up, pilih folder Windows tujuan dan klik "OK".
5. Saat makro selesai, folder Windows akan ditampilkan.
6. Di folder Windows ini, folder dan itemnya di bagian "Favorit" telah diekspor, seperti gambar layar berikut.

Pulihkan Data Outlook dari Cadangan

Sangat disarankan untuk mencadangkan file Outlook secara teratur. Itu karena jika Anda menderita kerusakan file Outlook, Anda bisa memulihkan Outlook data dari backup dengan mudah. Namun, jika Anda tidak memiliki cadangan seperti itu, Anda harus mencoba perbaikan Outlook yang sulit. Saat itu, alat perbaikan kotak masuk tidak akan banyak membantu. Anda harus membantu memperbaiki alat eksternal, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk sql rusak dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com