Cara Cepat Mengekspor Semua Hyperlink di Beberapa Email Outlook ke Excel

Saat Anda perlu mengekstrak semua hyperlink dalam satu atau lebih email, menyalinnya satu per satu adalah tindakan yang kurang efisien. Artikel ini akan mengajarkan Anda metode untuk mengekspor semua hyperlink dalam banyak email ke Excel dengan cepat.

Untuk beberapa alasan, seperti mencatat hyperlink di semua email terkirim, Anda harus mengekstrak hyperlink. Tanpa ragu, tidak disarankan untuk mengekstrak dan menyalinnya secara manual. Anda harus merindukan pendekatan yang jauh lebih cerdas, seperti menggunakan VBA. Di sini kami akan membagikan kepada Anda sepotong kode VBA, yang dapat mengekspor semua hyperlink di banyak email ke Excel dengan satu klik mudah.

Ekspor Semua Hyperlink di Banyak Email ke Excel

1. Pertama-tama, jalankan program Outlook Anda seperti biasa.
2. Kemudian, di jendela Outlook, Anda perlu menekan tombol "Alt + F11".
3. Sekaligus, Anda akan mendapatkan akses ke editor Outlook VBA.
4. Selanjutnya, Anda perlu mengaktifkan “Microsoft Word Object Library” serta “Microsoft Excel Object Library”. Klik “Tools” > “References” lalu aktifkan keduanya di kotak dialog pop-up.
5. Selanjutnya, Anda perlu membuka modul yang tidak digunakan, di mana Anda harus menyalin kode VBA di bawah ini ke dalam modul ini.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Setelah itu, Anda dapat keluar dari jendela editor VBA saat ini.
7. Kemudian akses "Opsi Outlook" untuk menyesuaikan Bilah Alat Akses Cepat guna menambahkan makro yang baru ditambahkan ke Bilah Alat Akses Cepat.
8. Akhirnya Anda bisa mengambil bidikan:

• Pertama, di daftar email, pilih email yang hyperlinknya ingin Anda ekstrak.
• Kemudian, klik tombol makro di Bilah Alat Akses Cepat.
• Saat makro selesai, Anda akan mendapatkan file Excel, seperti gambar di bawah ini:

Perbaiki Masalah Outlook yang Tidak Terduga

Masalah pada Outlook dapat terjadi dari waktu ke waktu tanpa pertanda apa pun. Namun, untuk kesalahan kecil, Outlook dapat pulih dengan memulai ulang atau melakukan pembaruan sederhana. alat perbaikan kotak masuk. Tetapi jika menghadapi beberapa masalah parah, sarana internal tidak akan berpengaruh. Pada titik ini, pilihan terakhir Anda jelas merupakan alat yang lebih bereputasi dan kuat, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk mdf rusak dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com