Cara Mengompresi Semua Lampiran dengan Cepat menjadi a Zip File di Email Outlook Anda

Terkadang, Anda mungkin ingin memampatkan semua lampiran dalam email menjadi file zip file langsung di Outlook. Dalam kasus ini, Anda dapat menggunakan kode VBA yang diperkenalkan di artikel ini untuk mendapatkan fitur ini.

Secara default, Outlook memiliki batas ukuran lampiran - 20 MB untuk POP3, IMAP, atau akun email berbasis web lainnya dan 10 MB untuk akun Exchange. Jadi, saat ukuran total lampiran melebihi batas, Anda akan mendapatkan error terkait. Dalam kasus ini, merupakan pilihan yang baik untuk memampatkan semua lampiran menjadi file zip file.

Namun, seperti yang Anda lihat, Outlook tidak menawarkan fitur langsung seperti itu. Artinya, Anda harus terlebih dahulu zip file-file ini di hard drive kemudian pasang kembali yang baru dibuat zip mengajukan. Nyatanya, most pengguna berharap bahwa mereka dapat langsung mencapainya dalam Outlook. Menanggapi kebutuhan ini, kami akan memperkenalkan cara menggunakan VBA untuk merealisasikannya sebagai berikut.

Kompres Semua Lampiran menjadi a Zip File

1. Pertama-tama, luncurkan aplikasi Outlook Anda.
2. Kemudian tekan tombol "Alt + F11" di jendela utama Outlook.
3. Berikutnya di jendela editor Outlook VBA baru, buka modul.
4. Selanjutnya, salin dan tempel kode VBA berikut ke dalam modul.

Sub ZipAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim objShell As Object
    Dim varTempFolder As Variant
    Dim varZipFile As Variant
 
    'Save the attachments to Temporary folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    varTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "dd-mm-yyyy- hh-mm-ss-")
    MkDir (varTempFolder)
    varTempFolder = varTempFolder & "\"
 
    Set objMail = Outlook.Application.ActiveInspector.CurrentItem
    Set objAttachments = objMail.attachments
    For Each objAttachment In objAttachments
        objAttachment.SaveAsFile (varTempFolder & objAttachment.FileName)
    Next
 
    'Create a new zip file
    varZipFile = InputBox("Specify a name for the new zip file", "Name Zip File", objMail.Subject)
    varZipFile = objFileSystem.GetSpecialFolder(2).Path & "\" & varZipFile & ".zip"
    Open varZipFile For Output As #1
    Print #1, Chr$(80) & Chr$(75) & Chr$(5) & Chr$(6) & String(18, 0)
    Close #1
 
    'Copy all the saved attachments to the new zip file
     Set objShell = CreateObject("Shell.Application")
     objShell.NameSpace(varZipFile).CopyHere objShell.NameSpace(varTempFolder).Items

     'Keep macro running until Compressing is done
     On Error Resume Next
     Do Until objShell.NameSpace(varZipFile).Items.Count = objShell.NameSpace(varTempFolder).Items.Count
        Application.Wait (Now + TimeValue("0:00:01"))
     Loop
     On Error GoTo 0
 
     'Delete all the attachments
     Set objAttachments = objMail.attachments
     While objAttachments.Count > 0
           objAttachments.Item(1).Delete
     Wend
 
     'Add the new zip file to the current email 
     objMail.attachments.Add varZipFile
 
    'Prompt
    MsgBox ("Complete!")
End Sub

5. Setelah itu, Anda perlu memeriksa pengaturan makro Outlook Anda untuk memastikan bahwa makro diizinkan.
6. Nanti Anda dapat menambahkan proyek VBA baru ke Quick Access Toolbar jendela pesan seperti biasa.
7. Akhirnya Anda bisa mencobanya.

• Pertama, buat email baru dan lampirkan beberapa file. Atau cukup buka email dengan banyak lampiran.
• Selanjutnya klik tombol makro di Bilah Alat Akses Cepat.
• Nanti Anda perlu menentukan nama untuk file zip file dan tekan "OK". Secara default, ini akan disetel sama seperti subjek email.
• Sekaligus, semua lampiran akan dikompresi menjadi zip file, seperti tangkapan layar berikut:

Unzip itu.Zip Lampiran Langsung di Outlook

Tidak dapat dipungkiri bahwa Anda akan menerima keterikatan apa pun dengan “.zipEkstensi file sekarang dan nanti. Dalam skenario ini, Anda mungkin ingin langsung unzip file tersebut dari dalam Outlook Anda alih-alih menyimpan dan membuka kompresinya di drive lokal. Meskipun Outlook tidak memiliki fitur asli seperti itu, Anda masih dapat menggunakan VBA untuk mendapatkannya juga. Untuk detail lebih lanjut, Anda dapat merujuk ke artikel lain - “Bagaimana Unzip itu.Zip Lampiran Langsung di Outlook melalui VBA".

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memperbaiki sql dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com