Cara Cepat Melampirkan Slide Tertentu dari a PowerPoint Presentasi ke Email Outlook Anda

Jika Anda ingin mengekstrak slide tertentu dari a PowerPoint presentasi ke presentasi baru yang terpisah dan melampirkannya ke email Outlook, Anda dapat memanfaatkan cara yang dibagikan dalam artikel ini.

Alih-alih melampirkan keseluruhan PowerPoint presentasi ke email, jika Anda ingin melampirkan slide presentasi tertentu, secara umum, Anda harus menyalin slide tertentu ke presentasi baru terlebih dahulu. Ini terlalu merepotkan. Oleh karena itu, di sini kami akan menunjukkan kepada Anda sebuah metode yang dapat mewujudkannya dalam sekali jalan.

Lampirkan Slide Tertentu dari a PowerPoint Presentasi ke Email

1. Pertama, buka spesifiknya PowerPoint presentasi.
2. Lalu, di PowerPoint jendela aplikasi, tekan tombol "Alt + F11" untuk mengakses editor VBA.
3. Selanjutnya, di jendela baru, buat modul baru dengan menekan “Sisipkan” > “Modul”.
4. Selanjutnya, salin dan tempel kode VBA berikut ke dalam modul ini.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Setelah itu, Anda dapat menutup jendela aktif.
6. Kemudian, buka “File” > “Options” > “Quick Access Toolbar” untuk menambahkan makro baru ke Quick Access Toolbar.
7. Terakhir, Anda dapat mencoba makro ini.

• Sebagai langkah awal, pilih slide spesifik yang ingin Anda ekstrak.
• Lalu, klik tombol makro di Bilah Alat Akses Cepat.
• Sekaligus, email Outlook akan muncul, di mana ada PowerPoint presentasi yang diekstraksi dari presentasi sumber.

Gunakan Alat Pemulihan yang Efektif

Seperti yang kita semua tahu, Outlook diberkahi dengan utilitas perbaikan bawaan – scanpst. Namun, itu hanya dapat mengatasi gangguan kecil di Outlook. Jika apa yang Anda hadapi adalah kerusakan serius, itu tidak akan membuat efek. Pada saat itu, Anda tidak punya pilihan selain menggunakan alat perbaikan lain yang kuat dan tepercaya, seperti DataNumen Outlook Repair. Dengan itu, Anda akan mampu menyelamatkan file Outlook Anda yang rusak.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk mdf rusak dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com