Cara Cepat Melampirkan File Modifikasi Terakhir di Folder Windows ke Email Outlook Anda

Terkadang, Anda mungkin ingin dengan cepat menemukan dan melampirkan file modifikasi terakhir di folder Windows tertentu ke email Outlook. Dalam hal ini, Anda dapat menggunakan metode yang diperkenalkan dalam artikel ini.

Beberapa pengguna ingin agar Outlook dapat dengan cepat menemukan dan menambahkan file yang terakhir diubah dalam folder Windows ke email, seperti file yang baru saja dibuat, diubah, atau disimpan. Namun, Outlook tidak menawarkan fitur langsung dan bawaan seperti itu. Oleh karena itu, berikut ini kami akan memaparkan kode VBA yang dapat mewujudkannya dengan mudah.

Lampirkan File Modifikasi Terakhir di Folder Windows ke Email

1. Pertama-tama, Anda harus meluncurkan aplikasi Outlook Anda.
2. Kemudian, setelah Anda masuk ke jendela utama Outlook, Anda dapat menekan tombol "Alt + F11".
3. Selanjutnya Anda akan berhasil mengakses jendela editor Outlook VBA.
4. Selanjutnya, Anda harus mencari dan membuka modul yang tidak digunakan.
5. Dan kemudian salin dan tempel kode VBA berikut ke jendela modul ini.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Setelah itu, Anda dapat keluar dari jendela editor VBA saat ini dan melanjutkan untuk menambahkan makro baru ke Bilah Alat Akses Cepat atau pita jendela Pesan.
7. Nanti Anda perlu mengubah tingkat keamanan makro Outlook Anda ke rendah.
8. Akhirnya Anda bisa mencobanya.

• Pertama, buat dan buat email Outlook baru seperti biasa.
• Kemudian tekan tombol makro di Quick Access Toolbar, seperti gambar di bawah ini:
• Selanjutnya Anda akan diminta untuk memilih folder sumber Windows dan tekan "OK".
• Jika ada file seperti itu di folder Windows yang dipilih, Anda akan mendapatkan prompt seperti screenshot berikut:
• Ketika Anda menekan "Ya", file ini akan dilampirkan sekaligus.

Selesaikan Masalah Outlook Sesegera Mungkin

Setiap kali Anda mengalami masalah Outlook, disarankan untuk menyelesaikannya sesegera mungkin. Dalam situasi ini, Anda sebaiknya mempersiapkan yang kuat Perbaikan Outlook alat sebelumnya, seperti DataNumen Outlook Repair. Ini mampu memperbaiki kesalahan PST dan menyelamatkan data Outlook Anda secara efektif.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk mdf rusak dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com