Cara Cepat Mengekstrak Semua Penerima dari Beberapa File Pesan Outlook (.msg)

Beberapa pengguna ingin dengan cepat mengekstrak semua penerima dari beberapa file pesan Outlook yang disimpan dari email Outlook. Sekarang, p iniost akan melihat ini untuk berbagi pendekatan cepat.

Untuk mengekstrak penerima dari satu file pesan Outlook, Anda cukup mengklik dua kali untuk membukanya lalu menyalin penerima di jendela Pesan yang dibuka. Namun, jika Anda perlu menangani sekumpulan file pesan Outlook, metode manual tidak cukup efisien. Jadi, Anda mungkin mencari cara yang jauh lebih efisien. Di sini kami akan memperkenalkan yang seperti itu kepada Anda. Baca terus untuk mengetahui detailnya.

Ekstrak Semua Penerima dari Beberapa File Pesan Outlook (.msg)

1. Untuk sebagaitart, dapatkan akses ke editor Outlook VBA sesuai dengan "Cara Menjalankan Kode VBA di Outlook Anda".
2. Selanjutnya, salin dan tempel kode VBA berikut ke dalam modul kosong.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Kemudian, pindahkan kursor ke subrutin pertama.
4. Selanjutnya, klik tombol "Run" atau tekan tombol "F5".
5. Kemudian, di kotak dialog popup, pilih folder Windows yang berisi file pesan Outlook (.msg) sumber.
6. Setelah memilih, klik "OK" untuk membiarkan makro terus berjalan.
7. Saat makro selesai, pesan yang mencantumkan semua alamat email penerima yang diekstrak akan muncul, seperti yang ditunjukkan pada gambar layar berikut.

Lindungi Data Outlook Anda dari Jeopardy

Data Outlook memang rentan terhadap korupsi. Oleh karena itu, melindungi data Outlook merupakan tugas yang cukup berat. Anda harus tekun membuat cadangan rutin untuk data Outlook. Selain itu, jika memungkinkan, adalah bijaksana dan disarankan untuk menyiapkan Outlook yang berpengalaman dan profesional Perbaikan PST alat, seperti DataNumen Outlook Repair, sehingga Anda dapat memperoleh penyelamatan dengan segera dan tepat waktu jika terjadi kerusakan Outlook.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memulihkan Sql Server dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com