Cara Secara Otomatis Mengambil Garis Tubuh Pertama sebagai Subjek sebelum Mengirim Email Outlook tanpa Subjek

Beberapa pengguna ingin Outlook secara otomatis mengambil baris pertama badan email sebagai subjek saat mengirim email yang tidak memiliki subjek. Nah, pada artikel kali ini, kami akan memperkenalkan metode untuk merealisasikannya melalui kode VBA.

Banyak pengguna sering lupa memasukkan subjek saat membuat dan mengirim email. Jadi, biasanya, mereka berharap Outlook dapat secara otomatis mengisi subjek pada baris pertama badan email jika email keluar tidak memiliki subjek. Selanjutnya, kami akan membagikan metode yang mudah dan praktis dengan Anda.

Otomatis Mengambil Baris Isi Pertama sebagai Subjek sebelum Mengirim Email tanpa Subjek

1. Pertama-tama, luncurkan aplikasi Outlook.
2. Kemudian, dengan mengikuti langkah-langkah di “Cara Menjalankan Kode VBA di Outlook Anda“, Anda bisa masuk ke editor VBA.
3. Selanjutnya, di editor VBA, tambahkan referensi ke “MS Word Object Library” sesuai dengan “Cara Menambahkan Referensi Pustaka Objek di VBA".
4. Nanti, salin kode di bawah ini ke dalam proyek "ThisOutlookSession".

Private WithEvents objInspectors As Outlook.Inspectors

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail And Inspector.CurrentItem.Subject = "" Then
       Inspector.CurrentItem.Subject = " "
    End If
End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
    Dim objMailSelection As Word.Selection
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       If Len(Trim(objMail.Subject)) = 0 Then
          If MsgBox("No subject! Whether to take first line as subject?", vbQuestion + vbYesNo) = vbYes Then
             Set objMailDocument = objMail.GetInspector.WordEditor
             Set objMailSelection = objMailDocument.Application.Selection
 
             objMailDocument.Range(0, 0).Select
             objMailSelection.MoveEnd wdLine
 
             'Take first line of body as subject
             objMail.Subject = objMailSelection.Text
          End If
       End If
     End If
End Sub

5. Setelah itu, letakkan kursor di subrutin “Application_Startup” dan tekan “F5”.
6. Akhirnya, Anda bisa mencobanya.

• Pertama-tama, buat dan tulis email dengan hanya subjek kosong.
• Kemudian, klik tombol “Kirim”.
• Nanti, Anda akan mendapat pesan yang menanyakan apakah akan menjadikan baris pertama tubuh sebagai subjek.
• Selama Anda memilih tombol "Ya", baris pertama dari badan email akan diekstraksi dan digunakan sebagai subjek dan email akan dikirim.

Amankan Data Outlook Anda

Tentu saja, ada beberapa email penting dan item lainnya di Outlook Anda. Oleh karena itu, Anda harus tidak mau menemukan kehilangan data Outlook. Kemudian, Anda harus mengambil beberapa tindakan, seperti membuat cadangan data reguler Outlook Anda, belajar menggunakan alat perbaikan bawaan untuk perbaiki Outlook kesalahan dan menyiapkan utilitas pemulihan eksternal yang kuat. DataNumen Outlook Repair adalah pilihan yang baik karena tingkat pemulihan PST-nya yang tinggi.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pemulihan sql dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com