Cara Mengekspor Struktur Folder File Outlook Anda ke Excel

Jika Anda ingin mengekspor struktur folder file data Outlook dengan cepat ke buku kerja Excel, Anda dapat menggunakan metode yang diperkenalkan dalam artikel ini.

Untuk beberapa alasan, seperti mencatat folder dan subfolder Outlook saat ini, banyak pengguna berharap untuk mengekspor struktur folder file Outlook ke file eksternal, seperti buku kerja Excel. Berikut ini, kami akan membagikan Anda sepotong kode VBA, yang dapat membantu Anda mencapainya dalam sekejap.

Ekspor Struktur Folder File Outlook Anda ke Excel

1. Untuk start dengan, luncurkan aplikasi Outlook Anda.
2. Kemudian, di jendela Outlook utama, tekan tombol "Alt + F11".
3. Selanjutnya, Anda akan masuk ke editor Outlook VBA, di mana Anda harus membuka modul yang tidak digunakan.
4. Selanjutnya, Anda dapat menyalin kode VBA berikut ke dalam modul ini.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

5. Setelah itu, Anda harus memastikan bahwa Outlook telah mengaktifkan makro.
6. Akhirnya, Anda dapat mengambil bidikan:

• Di jendela makro saat ini, tekan tombol tombol F5.
• Setelah makro selesai, Anda akan mendapatkan peringatan yang meminta "Selesai".
• Kemudian, Anda dapat menuju ke folder lokal yang telah ditentukan untuk menemukan file Excel baru. Buka dan akan terlihat seperti screenshot berikut:

Jangan Pernah Abaikan Kesalahan Outlook Apa Pun

Meskipun dengan jumlah kemampuan, Outlook sama rentan terhadap kesalahan dan korupsi seperti klien email lainnya. Oleh karena itu, Anda harus mementingkan semua kesalahan di Outlook Anda. Jangan abaikan mereka, tolong. Jika tidak, akumulasi kesalahan akhirnya dapat menyebabkan korupsi Outlook. Jika dihadapkan dengan kesalahan rumit, disarankan untuk menggunakan alat yang ampuh, seperti DataNumen Outlook Repair, Yang dapat perbaiki Outlook kesalahan dalam hitungan detik.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pemulihan sql dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com