Cara Batch Validasi Semua Hyperlink di Dokumen Word Anda melalui VBA

Pada artikel ini, kami akan menunjukkan kepada Anda cara otomatis untuk memvalidasi semua hyperlink dengan cepat dalam dokumen Word Anda melalui VBA.

Sebuah dokumen Word dapat berisi banyak hyperlink, bahkan ratusan. Di antaranya, beberapa di antaranya adalah tautan tidak valid yang gagal mengarahkan Anda ke laman web yang benar. Oleh karena itu, kami ingin menawarkan kepada Anda cara untuk memeriksa semua tautan dalam dokumen dengan cepat melalui VBA.

Instal dan Simpan Makro Word

1. Pertama-tama, buka editor VBA dengan "Alt + F11".
2. Kemudian klik proyek "Normal".
3. Selanjutnya klik tab “Insert” pada menu toolbar.
4. Dan pilih "Modul" di menu.
5. Klik dua kali pada modul untuk membuka ruang pengeditan dan tempel kode berikut di sana:

Function CheckURL(strURL As String) As Boolean
  Dim objDemand As Object
  Dim varResult As Variant
 
  On Error GoTo ErrorHandler
  Set objDemand = CreateObject("WinHttp.WinHttpRequest.5.1")
 
  With objDemand
    .Open "GET", strURL, False
    .Send
    varResult = .StatusText
  End With
 
  Set objDemand = Nothing
 
  If varResult = "OK" Then
    CheckURL = True
  Else
    CheckURL = False
  End If
 
ErrorHandler:
End Function

Sub ReturnURLCheck()
  Dim objLink As Hyperlink
  Dim strLinkText As String
  Dim strLinkAddress As String
  Dim strResult As String
  Dim nInvalidLink As Integer, nTotalLinks As Integer
  Dim objDoc As Document
 
  Application.ScreenUpdating = False
 
  Set objDoc = ActiveDocument
  nTotalLinks = objDoc.Hyperlinks.Count
  nInvalidLink = 0
 
  With objDoc
    For Each objLink In .Hyperlinks
      strLinkText = objLink.Range.Text
      strLinkAddress = objLink.Address
 
      If Not CheckURL(strLinkAddress) Then
        nInvalidLink = nInvalidLink + 1
        strResult = frmCheckURLs.txtShowResult.Text
        frmCheckURLs.txtShowResult.Text = strResult & nInvalidLink & ". Invalid Link Information:" & vbNewLine & _
                                          "Displayed Text: " & strLinkText & vbNewLine & _
                                           "Address: " & strLinkAddress & vbNewLine & vbNewLine
      End If
    Next objLink
 
    frmCheckURLs.txtTotalLinks.Text = nTotalLinks 
    frmCheckURLs.txtNumberOfInvalidLinks.Text = nInvalidLink
    frmCheckURLs.Show Modal
 
  End With
  Application.ScreenUpdating = True
End Sub

Sub HighlightInvalidLinks()
  Dim objLink As Hyperlink
  Dim strLinkAddress As String
  Dim strResult As String
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
 
  With objDoc
    For Each objLink In .Hyperlinks
      strLinkAddress = objLink.Address
 
      If Not CheckURL(strLinkAddress) Then
        objLink.Range.HighlightColorIndex = wdYellow
      End If
    Next objLink
  End With
End Sub

6. Selanjutnya klik “Simpan”.
7. Kemudian tetapkan tombol untuk makro. Anda dapat merujuk ke artikel berikut untuk informasi rinci:

Cara Menghapus Pemformatan Teks yang Disisipkan dengan Makro dan VBA di Word Anda

Buat Formulir Pengguna

Dengan formulir pengguna, Anda dapat dengan jelas melihat jumlah tautan dalam dokumen saat ini, jumlah tautan yang tidak valid, dan detail lainnya.

1. Pertama, klik "Sisipkan" di bilah alat lagi. Tapi kali ini, pilih "UserForm".
2. Selanjutnya tekan "F4" untuk membuka "Jendela Properti" di sudut kiri bawah. Ukuran jendela dapat disesuaikan.
3. Sekarang beri nama formulir pengguna sebagai "frmCheckURLs".
4. Setel keterangan sebagai "Periksa URL".
5. Kemudian atur font dengan benar.
6. Selanjutnya klik tombol “Toolbox” di toolbar.
7. Sekarang klik "Label" pada kotak alat. Gunakan mouse untuk menyeret label persegi panjang pada formulir pengguna.
8. Klik pada label untuk mengaktifkan jendela propertinya. Tetapkan nama label sebagai “lblInvalidURLs”, dan beri label keterangan sebagai “URL Tidak Valid:”.
9. Selanjutnya pilih font dan warna depan yang tepat untuk teks keterangan label.
10. Pilih "Kotak Teks" pada kotak alat dan masukkan kotak teks pada formulir pengguna. Sesuaikan ukurannya.
11. Kemudian atur nama kotak teks sebagai "txtShowResult".
12. Atur font dan warna depan sesuai keinginan.
13. Temukan "MultiLine", dan atur menjadi "True".
14. Temukan "Scrollbars" dan pilih bilah vertikal.
15. Selanjutnya buat dua label dan kotak teks lagi.
16. Kemudian beri nama label pertama sebagai “lblTotalLinks” dan atur keterangan sebagai “Total link dalam dokumen ini”.
17. Dan beri nama label kedua sebagai "lblNumberOfInvalidLinks" dan atur keterangan sebagai "Jumlah tautan tidak valid".
18. Beri nama kotak teks pertama sebagai "txtTotalLinks", dan yang kedua sebagai "txtNumberOfInvalidLinks".
19. Kemudian temukan kontrol tombol perintah pada kotak alat. Buat dua tombol perintah, seperti di bawah ini:
20. Beri nama tombol pertama sebagai "cmdbtnClose", dan teks keterangannya sebagai "Tutup".
21. Beri nama tombol kedua sebagai "btnCloseAndHighlightInvalidURLs", dan teks keterangannya sebagai "Tutup & Sorot URL Tidak Valid".
22. Selanjutnya klik dua kali pada tombol “Tutup” dan tombol “Tutup & Sorot URL Tidak Valid”. Masukkan kode sebagai berikut:

Jalankan Macro

Klik tombol yang Anda tetapkan ke makro. Inilah efek akhirnya:

Anda dapat melihat informasi terperinci tentang setiap tautan yang gagal di kotak teks besar sebelah kiri. Dan Anda dapat memilih untuk menutup formulir pengguna secara langsung atau menutupnya sambil menyorot semua tautan yang rusak dalam dokumen.

Tangani Masalah Kata dengan Hati-hati

Word mudah sekali melakukan kesalahan. Dengan demikian menjadi sangat penting untuk perbaiki Word dengan benar. Sebagian besar waktu, alat bawaan tidak dapat banyak membantu Anda. Oleh karena itu, pilihan terbaik Anda adalah mendapatkan alat perbaikan pihak ketiga.

Pengantar Penulis:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk perbaiki xlsx ke pdf memperbaiki produk perangkat lunak. Untuk informasi lebih lanjut kunjungi www.datanumen.com