Cara Batch Menghapus Semua Tanda Terima Baca di Outlook Anda

Untuk mengonfirmasi bahwa penerima telah membaca email Anda, Anda dapat meminta tanda terima telah dibaca saat membuat email. Dalam situasi ini, kotak surat Anda mungkin diisi dengan tanda dibaca seperti itu. Sekarang, p iniost akan mengajari Anda cara menghapusnya secara permanen.

Setelah membaca artikel "Cara Batch Menghapus Semua Tanda Terima Pengiriman di Outlook Anda“, Anda mungkin berpikir tentang pendekatan untuk menghapus semua tanda dibaca secara massal. Faktanya, perbedaan nyata antara kedua jenis tanda terima adalah subjeknya. Tanda terima pengiriman berisi subjek "Terkirim", tetapi tanda terima baca berisi "Sudah dibaca". Oleh karena itu, Anda dapat menggunakan cara yang sama untuk menghapus semua tanda terima baca. Berikut ini, kami akan mengajari Anda langkah-langkah konkret secara detail.

Hapus Batch Semua Tanda Terima Baca

1. Pada awalnya, start Outlook Anda.
2. Lalu, buka editor Outlook VBA melalui "Alt + F11" sesuai dengan "Cara Menjalankan Kode VBA di Outlook Anda".
3. Selanjutnya, di jendela baru, buka modul kosong dan masukkan kode berikut ke dalamnya.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Setelah itu, klik subrutin pertama.
5. Terakhir, tekan tombol "F5".
6. Sekaligus, makro akan bekerja untuk menghapus semua tanda terima baca dari Outlook Anda.
7. Setelah selesai, Anda akan mendapatkan prompt tentang hasilnya, seperti gambar di bawah ini.
8. Saat ini, Anda dapat memeriksa folder email Anda. Semua tanda terima telah dibaca telah hilang.

Pertahankan Data Outlook

Meskipun file Outlook memang rentan terhadap korupsi, kami dapat mengambil tindakan untuk menjaganya. Misalnya, kita harus menyimpan file Outlook dalam ukuran kecil, melindunginya dari faktor berbahaya dan mencadangkannya secara teratur. Last but not least, Anda sebaiknya menyiapkan alat perbaikan PST eksternal yang kuat, seperti DataNumen Outlook Repair. Ini akan berdampak besar pada perbaikan Outlook rusak file.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk perbaikan sql dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com