Cara Mengatur Outlook Online atau Offline Secara Otomatis Berdasarkan Jam Kerja Anda

Beberapa pengguna ingin agar Outlook beralih otomatis antara status online dan offline berdasarkan jam kerja mereka. Jadi, dalam artikel ini, kami akan membagikan metode cepat kepada Anda.

Sebenarnya, mengatur Outlook online atau offline sangatlah mudah. Untuk mengubah Outlook menjadi status offline, Anda cukup beralih ke tab "Kirim / Terima" dan tekan tombol "Bekerja Offline". Dan untuk kembali ke status online, cukup tekan tombol ini lagi. Namun, beberapa pengguna berharap Outlook dapat secara otomatis beralih ke status offline saat di luar jam kerja dan kembali online pada jam kerja. Meskipun Outlook tidak menyediakan fitur seperti itu, Anda masih dapat menggunakan kode VBA berikut untuk mencapainya.

Atur Outlook Online atau Offline Secara Otomatis Berdasarkan Jam Kerja Anda

1. Pertama-tama, jalankan aplikasi Outlook Anda.
2. Kemudian, setelah mendapatkan akses ke Outlook Anda, Anda harus membuka folder Tasks Anda.
3. Selanjutnya Anda harus membuat item Tugas berulang setiap hari.

• Klik tombol "Tugas Baru" di pita.
• Kemudian masukkan "Offline" di baris subjek Tugas.
• Selanjutnya klik pada tombol "Perulangan" di bawah tab "Tugas".
• Di kotak dialog popup, pilih pola pengulangan "Harian", aktifkan "Tanpa tanggal akhir" dan tekan "OK".
• Selanjutnya Anda harus mengaktifkan Pengingat pada "5:00 PM".
• Terakhir tekan tombol "Simpan & Tutup".

4. Selanjutnya, Anda perlu membuat Tugas berulang harian lainnya yang disebut "Online" dan mengaktifkan pengingat pada "8:00", yang ditunjukkan seperti gambar di bawah ini:
5. Setelah itu, di jendela utama Outlook, tekan tombol "Alt + F11".
6. Selanjutnya Anda akan mendapatkan akses ke editor Outlook VBA, di mana Anda perlu mencari dan membuka proyek "ThisOutlookSession".
7. Nanti salin kode VBA berikut ke dalam proyek ini.

Dim objNameSpace As Outlook.NameSpace

'Set Online/Offline Status on Outlook Startup
Private Sub Application_Startup()
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    'If now is before 8:00 AM or after 5:00 PM on Outlook startup
    If Now() < DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM# Or Now() > DateSerial(Year(Now), Month(Now), Day(Now)) + #5:00:00 PM# Then
 
       'If Outlook is online
       If objNameSpace.Offline = False Then
          'set it offline
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
 
       'If now is between 8:00 AM and 5:00 PM
    Else
 
       'If Outlook is offline
       If objNameSpace.Offline = True Then
          'Set it online
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
    End If
End Sub

'Change Online/Offline Status at Specific Time
Private Sub Application_Reminder(ByVal Item As Object)
    Dim objOfflineTask As Outlook.TaskItem
    Dim objOnlineTask As Outlook.TaskItem
 
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    If TypeOf Item Is TaskItem Then
       If Item.Subject = "Offline" Then
          Set objOfflineTask = Item
 
          'If Outlook is online when "Offline" task reminder alerts
          If objNameSpace.Offline = False Then
             'Set Outlook offline
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          'Clear the reminder by marking task complete
          objOfflineTask.MarkComplete
 
       ElseIf Item.Subject = "Online" Then
          Set objOnlineTask = Item
 
          'If Outlook is offline when "Online" task reminder alerts
          If objNameSpace.Offline = True Then
             'Set Outlook online
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          objOnlineTask.MarkComplete
 
       End If
    End If
End Sub

8. Pada akhirnya, Anda dapat memulai ulang Outlook untuk mengaktifkan makro ini.
9. Mulai sekarang, Outlook Anda akan online pada jam kerja dan otomatis beralih ke status offline di luar jam kerja.

Pilihan Terakhir Anda saat Outlook Crash

Meskipun Outlook menawarkan banyak fitur, Outlook tetap tidak dapat menghindari kesalahan dan kerusakan. Tapi jangan panik. Selama Anda melakukan tindakan pencegahan yang memadai, Anda masih bisa melindungi data Outlook Anda secara efektif. Misalnya, Anda harus mencadangkan file PST Anda secara teratur karena cadangan akan memungkinkan Anda untuk kembali PST korup data. Juga, menjaga alat perbaikan yang kuat, seperti DataNumen Outlook Repair, juga merupakan masalah kebutuhan.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk perbaiki mdf dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com