Cara Mengatur Secara Otomatis Waktu Pengingat yang Berbeda untuk Rapat Outlook dalam Kategori Warna Berbeda

Jika Anda mengklasifikasikan rapat Outlook menurut kategori warna dan ingin mengatur waktu pengingat berbeda untuk rapat dalam kategori warna berbeda, Anda bisa merujuk ke artikel ini. Di sini kami akan mengajari Anda untuk merealisasikannya dengan Outlook VBA.

Sebagai contoh, Anda membagi rapat menjadi dua kelompok. Satu kelompok berada dalam kategori warna "Di Luar Lokasi" karena lokasi rapat terlalu jauh, dan kelompok lainnya berada dalam kategori warna "Di Lokasi" karena lokasinya tepat di sini. Sekarang, Anda ingin Outlook dapat secara otomatis mengatur waktu pengingat untuk rapat "di luar lokasi" 1 jam sebelum dimulai dan rapat "di lokasi" 15 menit sebelum dimulai. Melihat kebutuhan ini, selanjutnya, kami akan membagikan metode singkat.

Atur Otomatis Pengingat Berbeda untuk Rapat dalam Kategori Warna Berbeda

1. Untuk memulainya, luncurkan aplikasi Outlook Anda.
2. Kemudian, tekan tombol "Alt + F11" untuk mengakses jendela editor VBA.
3. Selanjutnya, di jendela berikutnya, salin dan tempel kode VBA di bawah ini ke dalam proyek "ThisOutlookSession".

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Selanjutnya, Anda perlu mengklik subrutin “Application_Startup” dan menekan tombol “F5” untuk menjalankan makro ini.
5. Sejak itu, setiap kali pertemuan baru ditambahkan ke kalender default atau Anda mengubah pertemuan yang sudah ada, Outlook akan otomatis memeriksa kategori pertemuan dan secara otomatis mengatur waktu pengingat yang berbeda.

Hilangkan Kesalahan Outlook

Berbagai masalah dapat terjadi pada Outlook dari waktu ke waktu. Oleh karena itu, sangat penting bagi pengguna untuk mempelajari cara mengatasi masalah Outlook. Sebagai permulaan, sebaiknya Anda melakukan pencadangan data Outlook secara teratur. Selain itu, jika memungkinkan, disarankan untuk menyimpan cadangan data yang memadai. Perbaikan Outlook alat di dekatnya, seperti DataNumen Outlook Repair. Itu dapat memindai file PST Anda untuk mencari tahu masalah Outlook dan kemudian menyelesaikannya dengan mudah.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pemulihan sql dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com