Cara Otomatis Merekam Jumlah Total Email Masuk Setiap Hari dalam File Excel

Artikel ini akan mengajari Anda cara mengizinkan Outlook menghitung secara otomatis berapa banyak email yang Anda terima setiap hari dan menulis jumlahnya ke dalam file Excel.

Banyak pengguna diharuskan menghitung jumlah total email yang diterima setiap hari. Selain itu, untuk pemeriksaan yang lebih nyaman di masa mendatang, banyak yang terbiasa mencatat jumlah total ke dalam file Excel. Dalam hal ini, tentunya Anda bisa memilih untuk menghitung dan mencatat secara manual setiap hari. Namun, ini agak merepotkan. Dan terkadang Anda mungkin lupa melakukannya. Oleh karena itu, Anda harus menginginkan metode praktis, yang dapat membuat Outlook melakukannya secara otomatis. Menanggapi persyaratan ini, kami akan mengajari Anda cara menggunakan VBA untuk mewujudkannya sebagai berikut.

Rekam Otomatis Jumlah Total Email Masuk Setiap Hari dalam File Excel

1. Pertama-tama, luncurkan aplikasi Outlook Anda.
2. Kemudian tekan pintasan tombol “Alt + F11” di jendela utama Outlook.
3. Selanjutnya di jendela editor VBA popup, buka proyek "ThisOutlookSession".
4. Selanjutnya, salin dan tempel kode VBA berikut ke dalam proyek ini.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Selanjutnya, tanda tangani kode ini dan ubah pengaturan makro Outlook Anda untuk memperbolehkan makro yang ditandatangani.
6. Setelah itu, Anda perlu membuat tugas berulang setiap hari.

• Pertama, klik tombol "Tugas Baru" di panel Tugas.
• Di jendela popup New Task, klik tombol "Recurrence".
• Kemudian di kotak dialog berikutnya, pilih "Harian", "Setiap 1 hari" dan "Tanpa tanggal akhir" dan terakhir tekan "OK".
• Nanti ubah subjek tugas dan pengingat sesuai kebutuhan Anda.
• Terakhir, klik tombol "Simpan & Tutup".

7. Mulai sekarang, setiap kali peringatan pengingat tugas ini, Outlook akan secara otomatis menghitung email yang diterima kemarin dan kemudian mencatat nomor tersebut ke dalam file Excel, seperti gambar layar berikut:

Keluar dari Kehilangan Data PST Permanen

Tidak ada yang mau menerima kehilangan data PST permanen. Namun, file PST Outlook rentan terhadap kerusakan. Oleh karena itu, Anda harus melakukan tindakan pencegahan yang memadai, seperti membuat cadangan data PST yang konsisten dan mutakhir serta menyimpan Pemulihan PST alat di sekitarnya, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk perbaikan sql dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com