Cara Menyorot Otomatis Email Penting yang Belum Anda Balas di Outlook

Untuk mengingat untuk membalas email penting, Anda mungkin ingin Outlook menampilkan email penting yang belum Anda balas dalam warna nyata tertentu untuk menyorotnya. Nah, artikel ini akan mengajari Anda cara mendapatkannya.

Pernahkah Anda melewatkan email penting dan tidak membalasnya tepat waktu? Jika Anda pernah mengalami masalah seperti itu, mungkin Anda berharap Outlook dapat menyoroti email penting yang belum Anda balas. Sekarang, berikut ini, kami akan memandu Anda untuk mencapainya dengan VBA. Asalkan Anda tidak terbiasa dengan VBA, lihat artikel saya sebelumnya - “Cara Menjalankan Kode VBA di Outlook Anda"Sementara itu.

Sorot Otomatis Email Penting yang Belum Anda Balas

1. Pertama-tama, akses editor VBA melalui "Alt + F11" di Outlook.
2. Kemudian, di jendela baru, salin kode di bawah ini ke dalam proyek "ThisOutlookSession".

Private WithEvents objSentFolder As Outlook.Folder
Private WithEvents objSentMails As Outlook.Items
Private objInbox As Outlook.Folder

'On startup, auto update the replied status of the emails in Inbox
Private Sub Application_Startup()
    Set objSentFolder = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail)
    Set objSentMails = objSentFolder.Items
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateRepliedStatus(objInbox)
End Sub

'After sending an email, auto update the replied status of the emails in Inbox
Private Sub objSentMails_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       Call UpdateRepliedStatus(objInbox)
    End If
End Sub

Private Sub UpdateRepliedStatus(ByVal objFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objRepliedProperty As Outlook.UserProperty
    Dim strRepliedStatus As String
 
    'Write the replied status to a new user property of emails
    For i = objFolder.Items.Count To 1 Step -1
        If objFolder.Items(i).Class = olMail Then
           Set objMail = objFolder.Items(i)
 
           Set objRepliedProperty = objMail.UserProperties.Find("Replied", True)
           If objRepliedProperty Is Nothing Then
              Set objRepliedProperty = objMail.UserProperties.Add("Replied", olText, True)
           End If
 
           strRepliedStatus = objMail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x10810003")
           If (Not (strRepliedStatus = 102)) And (Not (strRepliedStatus = 103)) Then
              objRepliedProperty.Value = "No"
           Else
              objRepliedProperty.Value = "Yes"
           End If
 
           objMail.Save
        End If
    Next
End Sub

3. Setelah itu, pindahkan kursor ke “Application_Startup "dan tekan" F5 ".
4. Nanti, tutup jendela ini.
5. Selanjutnya, ikuti langkah-langkah di bawah ini untuk membuat aturan pemformatan bersyarat untuk item di Inbox.

• Pertama, alihkan ke folder "Kotak Masuk".
• Kemudian, beralih ke tab "Tampilan" dan klik "Pengaturan Tampilan".
• Di kotak dialog baru, klik tombol "Pemformatan Bersyarat".
• Di kotak dialog "Pemformatan Bersyarat" berikutnya, klik "Tambahkan" dan masukkan nama untuk aturan baru, seperti "Email Penting yang Tidak Dibalas".
• Kemudian, klik tombol "Font ..." dan atur gaya dan warna font di kotak dialog "Font" popup.
• Setelah menentukan font, tekan "Kondisi ..." di kotak dialog "Pemformatan Bersyarat".
• Selanjutnya, di layar "Filter", pada tab "Lanjutan", tambahkan dua filter.

1. “Pentingnya”> “sama dengan”> “Tinggi”
2. “Membalas”> “adalah (persis)”> “Tidak”

• Terakhir, klik serangkaian "OK" untuk menyimpan aturan pemformatan ini.

6. Setelah Anda kembali ke Inbox, semua email penting yang belum Anda balas telah disorot dalam font dan warna tertentu.

Jangan Lambat dalam Perlindungan Data Outlook

Banyak sekali pengguna yang masih berpikir bahwa korupsi data tidak akan pernah terjadi pada mereka. Kenyataannya, ide-ide seperti itu salah total dan berisiko. Most dari waktu ke waktu, kesalahan kecil dapat mengakibatkan hilangnya data dengan mudah. Misalnya, jika Anda secara tidak sengaja mengklik tautan berbahaya di email yang tidak dikenal, file Outlook Anda mungkin terinfeksi virus dan bahkan menjadi rusak. Oleh karena itu, Anda harus selalu berhati-hati dalam perlindungan data, seperti tetap dalam pencadangan PST biasa dan menyiapkan alat perbaikan yang ampuh, seperti DataNumen Outlook Repair, Yang dapat perbaiki Outlook masalah dalam sekejap.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memulihkan mdf dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com