4 Metode Cepat untuk Menghapus Hentian Halaman yang Tidak Diinginkan di Dokumen Word Anda

Dalam postingan ini, kita akan fokus memperkenalkan 4 metode cepat untuk menghapus pemisah halaman yang tidak diinginkan di dokumen Word Anda.

Word menyisipkan pemisah halaman otomatis saat berpindah dari satu halaman ke halaman berikutnya. Selain itu, Anda dapat menyisipkan pemisah halaman manual setelah akhir rentang teks. Dengan demikian, teks akan dimulai di bagian atas halaman berikutnya. Untuk cara menyisipkan pemisah halaman manual, Anda dapat merujuk ke artikel ini: 5 Cara Cepat Memasukkan Halaman ke Dokumen Word Anda

Namun, Anda harus memahami bahwa Hentian halaman otomatis tidak terlihat dan karenanya tidak dapat dihapus secara manual. Tapi jeda halaman manual yang disisipkan lakukan. Jadi artikel kami terutama akan menawarkan pendekatan yang berguna untuk menghapus jeda halaman manual yang tidak diinginkan dalam dokumen Word.   

Metode 1: Hapus Hentian Halaman Secara Manual

1. Pertama-tama, Anda harus mengklik perintah "Tampilkan / Sembunyikan" di bawah tab "Beranda" untuk menampilkan semua tanda dan simbol tersembunyi dalam dokumen sehingga Anda dapat melihat hentian halaman.
2. Selanjutnya, pilih hentian halaman dan tekan "Hapus" untuk menyingkirkannya.
3. Atau Anda dapat mengklik di sebelah kiri hentian halaman dan kemudian menekan "Hapus".

Metode 2: Gunakan Fitur "Temukan dan Ganti"

1. Untuk memulai, tekan "Ctrl + H" untuk memicu kotak "Temukan dan Ganti".
2. Kemudian tempatkan kursor di dalam kotak teks "Temukan apa" dan klik tab "Lainnya".
3. Selanjutnya klik "Special" dan pilih "Manual Page Break" pada menu itu.
4. Terakhir, biarkan kotak "Replace with" kosong dan klik "Replace All" untuk menghapus setiap hentian halaman dalam dokumen.

Metode 3: Jalankan Makro untuk Menghapus Semua Hentian Halaman dalam Dokumen

1. Pertama, picu editor VBA di Word dengan menekan "Alt + F11".
2. Selanjutnya klik proyek "Normal" di kolom kiri.
3. Kemudian klik "Sisipkan" pada bilah menu dan pilih "Modul".
4. Buka modul dengan klik dua kali dan tempel kode berikut di sana:

Sub DeleteAllPageBreaksInOneDoc()
  Application.ScreenUpdating = False
 
  With Selection
    .HomeKey Unit:=wdStory
    With Selection.Find
      .ClearFormatting
      .Replacement.ClearFormatting
      .Text = "^m"
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute Replace:=wdReplaceAll
    End With
  End With
  MsgBox ("All manual page breaks in the document have been removed!")
 
  Application.ScreenUpdating = True
End Sub

5. Terakhir, tekan "F5" untuk mengeksekusi kode.

Metode 4: Hapus Semua Hentian Halaman di Semua Dokumen dalam Folder

Untuk menghapus semua hentian halaman di semua dokumen dalam folder, Anda dapat menggunakan metode ini.

1. Untuk menginstal dan menjalankan makro, Anda dapat merujuk ke langkah-langkah di metode 3.
2. Dan ingatlah untuk mengganti dengan makro di bawah ini:

Sub DeleteAllPageBreaksInAFolder()
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
 
  Application.ScreenUpdating = False
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
 
    With Selection
      .HomeKey Unit:=wdStory
      With Selection.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Text = "^m"
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
        .Execute Replace:=wdReplaceAll
      End With
    End With
    objDoc.Save
    objDoc.Close
    strFile = Dir()
  Wend
  Application.ScreenUpdating = True
End Sub

Makro tersebut akan memunculkan jendela “Telusuri”. Pilih folder yang berisi dokumen target Anda dan klik “OK” untuk melanjutkan.

Bersiap untuk Bencana Data

Banyak dari Anda telah menyadari hilangnya data secara acak. Untuk pengguna Word, disarankan juga untuk bersiap dengan baik menghadapi bencana data apa pun. Dan salah satu cara terbaik adalah dengan mendapatkan file perbaikan docx alat sebelumnya.

Pengantar Penulis:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk xlsx pemulihan ke pdf memperbaiki produk perangkat lunak. Untuk informasi lebih lanjut kunjungi www.datanumen.com