2 Cara Cepat Menggabungkan Beberapa Dokumen Word menjadi Satu melalui VBA

Pada artikel ini, kami dengan senang hati berbagi dengan Anda 2 cara untuk menggabungkan beberapa dokumen Word dengan cepat menjadi satu melalui VBA.

Di Word, ada fitur bawaan bawaan untuk membantu pengguna menggabungkan atau menggabungkan beberapa dokumen menjadi satu. Detailnya dijelaskan dalam artikel ini: Bagaimana Menggabungkan & Menggabungkan Beberapa Dokumen Word menjadi Satu

Dengan metode itu, Anda harus membuat beberapa klik dan isi dokumen berikutnya selalu tepat setelah yang sebelumnya. Oleh karena itu, kami ingin menawarkan Anda cara yang lebih cepat untuk melakukannya.

Metode 1: Gabungkan Dokumen yang Dipilih menjadi Satu

1. Pertama dan terpenting, buat dokumen kosong baru.
2. Picu editor VBA di Word dengan menekan “Alt+ F11”.
3. Selanjutnya klik "Normal".
4. Kemudian klik "Sisipkan".
5. Dan pilih "Modul".
6. Klik dua kali pada modul baru untuk membuka ruang pengeditan.
7. Tempel makro berikut di sana:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Selanjutnya klik "Run" atau tekan "F5".
9. Sekarang di jendela "Browse", pilih beberapa file dengan menekan "Ctrl" dan klik "OK".
10. Kemudian, semua isi dalam file yang dipilih akan digabungkan dalam dokumen baru, dengan teks dari setiap dokumen dimulai pada halaman baru.

Catatan:

Seperti yang kami sebutkan, makro ini menempatkan teks dari setiap dokumen pada halaman baru. Tetapi jika Anda membutuhkannya satu demi satu, Anda dapat mengubah beberapa baris kode di makro. Cari saja baris “If nEachSelectedFile < nTotalFiles Then”, hapus dan juga enam baris berikutnya.

Metode 2: Gabungkan Semua Dokumen dalam Folder menjadi Satu

Jika Anda memiliki folder file yang akan digabungkan, maka makro ini akan berfungsi dengan baik.

1. Sebagai langkah awal, instal dan jalankan makro seperti yang dijelaskan pada metode 1.
2. Kemudian ganti makro dengan yang ini:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Jalankan makro dengan mengklik "Jalankan".
4. Selanjutnya Anda melihat jendela "Browse" terbuka. Pilih folder tempat Anda menyimpan semua dokumen. Dan klik "Oke".

Demikian pula, teks setiap dokumen dimulai pada halaman baru. Untuk membuat teks-teks tersebut berurutan, temukan dan hapus baris kode “.InsertBreak Type:=wdPageBreak”.

Lindungi Dokumen Word Anda dengan Benar

Salah satu cara terbaik untuk melindungi dokumen Word Anda adalah dengan mencadangkannya secara teratur. Dengan cadangan di tangan, Anda tidak perlu takut kehilangan data. Selain itu, disarankan juga untuk mendapatkan alat untuk perbaiki docx jika salah satu dari mereka akan rusak.

Pengantar Penulis:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk Excel rusak ke pdf memperbaiki produk perangkat lunak. Untuk informasi lebih lanjut kunjungi www.datanumen.com