2 Cara Mencetak Daftar Tugas Outlook dengan Kategori Berbeda di Halaman Berbeda

Jika Anda telah menetapkan berbagai kategori warna ke tugas Outlook Anda dan sekarang ingin mencetak daftar tugas dengan kategori berbeda di halaman berbeda, Anda bisa merujuk ke artikel ini. Di sini kami akan membagikan kepada Anda 2 metode untuk mendapatkannya.

Untuk mengklasifikasikan dan mengelola tugas Anda dengan baik, mungkin Anda telah menerapkan kategori warna pada tugas Anda. Sekarang, jika Anda ingin mencetak daftar tugas Anda dengan kategori yang berbeda di halaman yang berbeda, silakan baca terus. Berikut ini, kami akan memperkenalkan Anda 2 cara untuk mendapatkannya.

Metode 1: Cetak Daftar Tugas Secara Manual Satu per Satu

1. Pertama, di Outlook, akses panel "Tugas".
2. Kemudian, buka folder Tugas.
3. Selanjutnya, tekan "Ctrl + E" untuk mengaktifkan pita "Cari".
4. Setelah itu, pada tab “Search”, klik tombol “Categorize”.
5. Dari daftar drop-down, pilih kategori warna.
6. Kemudian, hanya tugas dengan kategori yang dipilih yang akan tersisa dalam daftar.
7. Sekarang, buka "File"> "Cetak" untuk mencetak daftar tugas ini.
8. Selanjutnya, dengan cara yang sama, cetak daftar tugas dengan kategori warna lain satu per satu secara manual.

Metode 2: Cetak Batch Daftar Tugas oleh VBA

1. Pada awalnya, picu editor VBA sesuai dengan “Cara Menjalankan Kode VBA di Outlook Anda".
2. Kemudian, tambahkan referensi ke “MS Excel Object Library” sesuai dengan “Cara Menambahkan Referensi Pustaka Objek di VBA".
3. Selanjutnya, salin kode VBA berikut ke dalam modul.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Setelah itu, tekan tombol tombol “F5” untuk menjalankan makro ini segera.
5. Saat makro selesai, daftar tugas dengan kategori berbeda akan dicetak di halaman berbeda, seperti yang diperlihatkan dalam tangkapan layar berikut.

Dapatkan Kembali Data Berharga dari File PST yang Disusupi

Jika Anda tunduk pada file PST yang tidak dapat diakses, langkah Anda selanjutnya tidak diragukan lagi Perbaikan PST. Dalam hal ini, Anda dapat mencoba alat perbaikan kotak masuk terlebih dahulu. Asalkan gagal, Anda dapat melanjutkan untuk mencoba alat eksternal lain, seperti DataNumen Outlook Repair. Ini dapat memulihkan data PST dalam waktu cepat.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memulihkan mdf dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com