2 Metode untuk Mengirim Sel Terpilih dengan Cepat di Lembar Kerja Excel sebagai Email Outlook

Terkadang, Anda mungkin ingin menyisipkan sel yang dipilih dengan cepat di lembar kerja Excel ke email Outlook dan mengirimkan email ini. Artikel ini akan melihat keinginan untuk menawarkan 2 metode ini.

Artikel saya sebelumnya "2 Metode Cepat untuk Mengirim Lembar Kerja Excel sebagai Email Outlook”Telah mengajari Anda cara mengirim seluruh lembar kerja Excel sebagai email. Namun, terkadang, Anda hanya ingin mengirim sel yang dipilih di lembar kerja sebagai email. Menanggapi persyaratan ini, di sini kami akan memaparkan kepada Anda 2 metode. Anda dapat memilih sesuai preferensi Anda.

Metode 1: Salin Sel yang Dipilih ke Email Secara Manual

1. Pertama-tama, buka file Excel sumber dan akses lembar kerja Excel yang tepat.
2. Kemudian pilih sel yang ingin Anda kirim sebagai email Outlook.
3. Selanjutnya tekan pintasan tombol "Ctrl + C" untuk menyalin sel yang dipilih.
4. Setelah itu, luncurkan aplikasi Outlook Anda.
5. Selanjutnya, klik tombol "Email Baru" di pita "Beranda" untuk membuat email Outlook baru.
6. Kemudian di jendela Pesan baru, klik di bagian badan pesan.
7. Dan kemudian tekan tombol "Ctrl + V" untuk menempelkan sel Excel yang dipilih sebelumnya disalin.
8. Terakhir, Anda dapat menulis email seperti biasa dan klik tombol "Kirim" untuk mengirimkannya.

Metode 2: Kirim Sel yang Dipilih sebagai Email melalui VBA

1. Pertama-tama, buka buku kerja Excel sumber.
2. Kemudian tekan tombol "Alt + F11" untuk mengakses editor Excel VBA.
3. Di jendela baru, klik "Sisipkan"> "Modul" untuk memasukkan modul baru.
4. Selanjutnya, aktifkan Microsoft Outlook Object. Klik “Tools” > “References”. Pada kotak dialog pop-up, temukan dan centang “Microsoft Outlook Object Library”.
5. Selanjutnya, salin kode VBA berikut ke dalam modul ini.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Akhirnya, Anda bisa mencobanya.

• Pertama, pilih sel tertentu seperti biasa.
• Kemudian kembali ke makro baru dan tekan tombol F5 untuk memicunya.
• Segera, email Outlook baru akan ditampilkan, di mana Anda dapat melihat bahwa sel yang dipilih telah dimasukkan ke dalam badan email, seperti gambar layar berikut:

File PST Sama Rentannya dengan File Excel

Seperti yang kita ketahui, file Excel dan dokumen Word rentan terhadap kerusakan. Sebenarnya, hal yang sama berlaku untuk file PST, yang berisi semua item di kotak surat Outlook Anda. Jadi, mengamankan data PST Anda adalah tugas yang sulit. Salah satu tindakan paling efektif adalah dengan mencadangkan file secara teratur. Selain itu, untuk memberikan penyelamatan segera, sebaiknya Anda menyiapkan alat yang berpengalaman, seperti... DataNumen Outlook Repair, yang mampu memulihkan Outlook data tanpa bersusah payah.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk perbaiki mdf dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com