A szavazási statisztikák gyors exportálása egy Outlook e-mailből Excel-munkalapba

Ha szavazógombokat tartalmazó e-mailt küldött, miután a címzettek elküldték a válaszaikat, érdemes lehet megszámolni és exportálni a szavazási statisztikákat egy Excel-munkalapra. Tehát ebben a post, megtanítjuk, hogyan érd el gyorsan.

Az Outlook olyan erős, hogy még „szavazás” funkciót is kínál. Előző cikkem "Az MS Outlook ügyes használata szavazáshoz” megtanította a hatékony felhasználásra. Továbbá, most A szavazás után bizonyos okok miatt folytathatja a szavazási statisztikák exportálását egy Excel munkalapba, például ha ki szeretné nyomtatni a statisztikákat. De az Outlook ezt alapértelmezés szerint nem támogatja. Így a következőkben megtanítjuk, hogyan lehet ezt parafaszerűen megvalósítani.

Szavazási statisztikák exportálása e-mailben Excel-munkalapba

1. A legelején indítsa el az Outlook alkalmazást.
2. Ezután meg kell nyomnia az „Alt + F11” billentyűket az Outlook főablakában.
3. Ezután a „Microsoft Visual Basic for Applications” ablakban engedélyeznie kell a „Microsoft Excel Object Library”. Kattintson az „Eszközök” > „Referencia” elemre. Ezután a felugró párbeszédpanelen jelölje be a „Microsoft Excel Object Library”, és végül nyomja meg az „OK” gombot.
4. Ezt követően új modult helyezhet be, vagy megnyithat egy használaton kívüli modult.
5. Ezt követően másolja ki és illessze be a következő VBA-kódokat ebbe a modulba.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Ezt követően a kényelmes hozzáférés érdekében jobb, ha hozzáadja az új makrót a Gyorselérési eszköztárhoz.
6. Végül megpróbálhatod.

• Először válasszon ki egy forrás e-mailt, amely szavazógombokat tartalmaz.
• Ezután kattintson a makró gombra a Gyorselérési eszköztárban.
• A makró futtatása után tallózhat az előre meghatározott helyi mappába, amelyben egy új Excel-munkafüzet jelenik meg.
• Nyissa meg ezt az Excel-munkafüzetet. Most látni fogja a szavazási statisztikákat, az alábbi képen látható módon:

Senki sem tudja alaposan elhárítani az Outlook hibáit

Bár az Outlook számos funkcióval rendelkezik, nincs ilyen funkció, amely segítene elkerülni az Outlook hibáit. Mindenféle tényező okozhat Outlook-hibákat. Ha például gyakran helytelenül lép ki az Outlookból, akkor valószínűleg szenvedni fog PST korrupció. Ebben az esetben nincs más választása, mint néhány hatékony eszköz használata a PST-fájl megmentésére, mint pl. DataNumen Outlook Repair. Sok dicséretet kapott a magas helyreállítási arány miatt.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve korrupt mdf és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com