Hogyan lehet gyorsan exportálni az Outlook-találkozókra fordított teljes időt az egyes színkategóriákban

Ha jelentést szeretne készíteni az egyes színkategóriákban a találkozókkal eltöltött teljes időről, használhatja a cikkben bemutatott módszert. Segítségével gyorsan elvégezheti ezt, anélkül, hogy manuálisan kellene számolnia.

Sok felhasználó hozzászokott, hogy tevékenységeinek nagy részét az Outlook naptárban naplózza. A könnyebb kezelés és megkülönböztetés érdekében kategóriákat rendelnek hozzájuk. Ebben az esetben egyes felhasználók olyan jelentést szeretnének készíteni, amely az egyes színkategóriákban lévő naptári elemekre fordított teljes időt mutatja. Kétségtelen, hogy a manuális számolás és bevitel nehézkes. Ezért itt megosztunk egy módszert, amellyel ezt a feladatot egyetlen kattintással elvégezheti.

A találkozókra fordított teljes idő exportálása az egyes színkategóriákban

1. Először is indítsa el az Outlook alkalmazást.
2. Ezután az Outlook ablakba való belépés után megérintheti az „Alt + F11” billentyűket.
3. Ezt követően hozzáférhet a „Microsoft Visual Basic for Applications” ablakhoz.
4. Ezután engedélyezned kell a „Microsoft Excel objektumtárat”. Ehhez kattints az „Eszközök” > „Referencia” menüpontra.
5. Ezután meg kell találnia és meg kell nyitnia egy nem használt modult.
6. Ezt követően be kell másolnia a következő VBA-kódot ebbe a modulba.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Végül elindíthatja ezt a makrót, függetlenül attól, hogy rákattint a „Futtatás” ikonra az eszköztáron, vagy megnyomja az „F5” gombot.
8. Ezután ki kell választania egy adott naptárt.
9. Miután kiválasztotta és megnyomta az „OK” gombot, a makró tovább fut. Miután befejeződött, egy új Excel-fájl jelenik meg a háttérben.
10. Hozzáférhetsz. A következő képernyőképhez hasonlóan fog kinézni:

Tartsa szemmel az Outlook körüli potenciális veszélyeket

Az Outlook-felhasználóknak figyelniük kell az összes lehetséges kockázatra, beleértve az ismeretlen e-mail mellékleteket, a beágyazott hivatkozásokat és az emberi hibákat. Ellenkező esetben az Outlook bármikor megsérülhet. Ezenkívül elengedhetetlen az Outlook adatok rendszeres biztonsági mentése és egy speciális javítóeszköz vezetése. DataNumen Outlook Repair az egyik leginkább ajánlott javítóeszköz. Képes javítás Outlook problémák egy pillanat alatt.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sérült mdf és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com