Hogyan lehet gyorsan exportálni az Outlook kapcsolattartó csoport összes tagjának adatait Excelbe

Alapértelmezés szerint csak a névjegycsoport tagjainak neveit és e-mail címeit láthatja. Ha szeretné megtudni a tagok egyéb adatait, használja az ebben a cikkben bemutatott módszert.

Ha duplán kattint egy névjegycsoport megnyitásához, annak ablakában csak a csoporttagok nevét és e-mail címét láthatja. Nem férhet hozzá a tagok egyéb adataihoz, például céghez, beosztáshoz, telefonszámhoz vagy üzleti címhez stb. Általánosságban elmondható, hogy ezeknek az adatoknak a megtekintéséhez manuálisan kell megkeresnie a tagokhoz tartozó névjegyeket a Névjegyek mappában. Túlságosan zavaró. Itt bemutatunk egy VBA-kódot, amely gyorsan exportálhatja ezeket a részleteket egy Excel-munkafüzetbe.

Exportálja a kapcsolattartó csoport összes tagjának adatait Excelbe

1. Kezdésként indítsa el az Outlook alkalmazást.
2. Ezután nyomja meg az „Alt + F11” billentyűparancsokat az Outlook főablakában.
3. Ezután az új „Microsoft Visual Basic for Applications” ablakban meg kell nyitnia egy használaton kívüli modult, vagy közvetlenül be kell illesztenie egy új modult.
4. Ezt követően másolja ki és illessze be a következő VBA-kódot ebbe a modulba.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Ezt követően a kényelmes ellenőrzés érdekében hozzáadhatja az új VBA-projektet a Gyorselérési eszköztárhoz vagy a szalaghoz.
6. Később állítsa alacsonyra az Outlook makró biztonsági szintjét.
7. Végül is kipróbálhatod.

• Először válasszon ki egy kapcsolati csoportot.
• Ezután nyomja meg a makró gombot a Gyorselérési eszköztáron vagy a szalagon.
• A makró azonnal elindul.
• Amikor befejeződik, a „Befejezve!” üzenet jelenik meg.
• Ezt követően léphet az előre meghatározott célhelyi mappába, amelyben egy új Excel fájlt találhat.
• Nyissa meg, és látni fogja a csoport tagjainak elérhetőségeit, például a következő képernyőképet:

Ne essen pánikba az Outlook-problémák miatt

Senki sem hajlandó elfogadni semmilyen Outlook-problémát, nem számít felugró hibaüzenet vagy korrupt Outlook adatfájl. Ezért a felhasználók pánikba esnek, amikor Outlook-problémákkal találkoznak. Ha ilyenkor meg akarod őrizni a higgadtságot, akkor két szükségleted legyen a kezedben. Az egyik a jelenlegi Outlook adatmentések. A másik egy hatékony Outlook javító szoftver, mint pl DataNumen Outlook Repair.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sql helyreállítás és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com