Hogyan lehet gyorsan rögzíteni az adott diákat a PowerPoint Prezentáció az Outlook e-mailben

Ha ki szeretné bontani a konkrét diákat a PowerPoint prezentációt egy külön új prezentációba, és csatolja egy Outlook e-mailhez, használhatja a cikkben ismertetett módszert.

Ahelyett, hogy egy egészet csatolna PowerPoint prezentációt egy e-mailbe, ha a prezentáció adott diáit szeretné csatolni, általában először át kell másolnia az adott diákat egy új bemutatóba. Ez túlságosan zavaró. Ezért itt egy olyan módszert mutatunk be, amellyel egy lépésben megvalósítható.

Csatolja a konkrét diákat a PowerPoint Prezentáció e-mailben

1. Először nyissa meg a konkrét PowerPoint bemutatás.
2. Aztán a PowerPoint alkalmazás ablakában nyomja meg az „Alt + F11” billentyűket a VBA-szerkesztő eléréséhez.
3. Ezután az új ablakban hozzon létre egy új modult a „Beszúrás” > „Modul” megnyomásával.
4. Ezt követően másolja ki és illessze be a következő VBA-kódot ebbe a modulba.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Ezt követően bezárhatja az aktuális ablakot.
6. Később lépjen a „Fájl” > „Opciók” > „Gyorselérési eszköztár” menüpontra, hogy hozzáadja az új makrót a Gyorselérési eszköztárhoz.
7. Végül kipróbálhatja ezt a makrót.

• Mert minttart, válassza ki a kibontani kívánt diákat.
• Ezután kattintson a makró gombra a Gyorselérési eszköztárban.
• Egyszerre megjelenik egy Outlook e-mail, amelyben van a PowerPoint prezentáció, amely a forrásprezentációból származik.

Használjon hatékony helyreállítási eszközt

Mint mindannyian tudjuk, az Outlook beépített javító segédprogrammal rendelkezik – scanpst. Ennek ellenére egyszerűen megbirkózik az Outlook apró hibáival. Ha az, amivel szembesül, az súlyos károkat okoz, annak nem lesz hatása. Ekkor nincs más választása, mint egy másik hatékony és megbízható javítóeszközhöz, mint pl DataNumen Outlook Repair. Ezzel képes lesz megmenteni a sérült Outlook-fájlt.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sérült mdf és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com