Hogyan állíthat be különböző alapértelmezett emlékeztető időt az Outlook különböző típusú megjelölt elemeihez

Alapértelmezés szerint az Outlook automatikusan a feladatok alapértelmezett emlékeztető idejét használja minden megjelölt elemhez. Mégis, ha a megjelölt tételekhez tételtípus alapján eltérő emlékeztető időt szeretne használni, hivatkozhat a cikkben bemutatott módszerre.

Az Outlook lehetővé teszi az alapértelmezett emlékeztető idő beállítását az összes megjelölt elemhez, az elem típusától függetlenül. Lépjen a „Fájl” menübe, és kattintson az „Opciók” gombra. Ezután az „Outlook beállításai” ablakban láthatja az „Alapértelmezett emlékeztető ideje” opciót a „Feladatok” lapon, amint az a következő képernyőképen látható.

Mindazonáltal a legtöbb felhasználó eltérő emlékeztetői időt szeretne használni a különböző megjelölt elemekhez, például „9:00”-t a megjelölt e-mailekhez és „17:30”-at a megjelölt névjegyekhez. A következőkben erre a példára fogunk összpontosítani egy módszer bemutatásához.

Állítson be eltérő alapértelmezett emlékeztető időt a különböző típusú megjelölt elemekhez

1. Kezdésként indítsa el az Outlook alkalmazást.
2. Ezután nyissa meg az Outlook VBA szerkesztőjét a „A VBA kód futtatása az Outlookban".
3. A következő „Microsoft Visual Basic for Applications” ablakban másolja a következő kódot a „ThisOutlookSession” projektbe.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Ezután indítsa újra az Outlookot a makró aktiválásához.
5. Mostantól minden alkalommal, amikor megjelöl egy e-mailt, az emlékeztető időpontja „10:00” lesz a megjelölés esedékessége napján.
6. És amikor megjelöl egy névjegyet, az emlékeztető ideje „17:30” lesz a megjelölés esedékessége napján.

Rugalmasan kezelje az Outlook-problémákat

Az Outlookban mindenféle problémába ütközhetsz. Ezért előre meg kell tanulnod néhány intézkedést a kezelésükhöz. Például, ha az Outlook gyakran újraindul, javítanod kell az Office-t, vagy le kell tiltanod a harmadik féltől származó bővítményeket stb. Vagy ha az Outlook PST fájlod veszélybe kerül, először próbáld ki a postafiók javító eszköz. Ha meghiúsul, továbbra is igénybe vehet egy hatékony külső eszközt, mint pl DataNumen Outlook Repair.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve mdf helyreállítás és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com