Különböző betűszínek automatikus használata az e-mailek megválaszolásához és továbbításához az Outlook VBA segítségével

Alapértelmezés szerint nem engedélyezheti, hogy az Outlook automatikusan különböző betűszíneket használjon az e-mailek megválaszolásához és továbbításához. Ezért, ha van ilyen követelménye, akkor ezt a post okos megközelítés elsajátítására.

Az Outlook csak az e-mailek megválaszolásához és továbbításához használt betűtípus megadását teszi lehetővé. Léphet a „Fájl” > „Opciók” menüpontra. Ezután az „Outlook beállításaiban” lépjen a „Levelezés” fülre, és kattintson az „Irodák és betűtípusok…” gombra. A következő ablakban az „Üzenetek megválaszolása vagy továbbítása” részben láthatja a „Betűtípus” gombot. Kattintson rá, majd beállíthat egy adott betűszínt az e-mailek megválaszolásához és továbbításához.

Sok felhasználó azonban azt reméli, hogy különböző betűszíneket használ az e-mailek megválaszolásához vagy továbbításához. Az Outlook ugyan nem biztosít erre közvetlen szolgáltatásokat, de VBA kóddal mégis megvalósítható. Most olvassa el, hogy egy ilyen darab VBA-kódot kapjon.

Automatikusan használjon különböző betűszíneket az e-mailek megválaszolásához és továbbításához

1. Mert minttart, indítsa el az Outlook alkalmazást.
2. Ezután indítsa el a VBA-szerkesztőt a „A VBA kód futtatása az Outlookban".
3. Ezt követően a „Hogyan adjunk hozzá egy Object Lib-etrary Hivatkozás a VBA-ban“, adja hozzá a hivatkozást az „MS Word Object Library ”.
4. Ezt követően másolja be a következő kódot a „ThisOutlookSession” projektbe.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Ezt követően restart Outlook a makró aktiválásához.
6. Végre egy próbát tehetsz.

• Válasszon vagy nyisson meg egy e-mailt.
• Ezután kattintson a „Válasz” gombra. Az e-mailre válaszolva beírhat néhány szót a törzsbe. A betűszínnek rózsaszínnek kell lennie.
• Vagy kattintson a „Válasz mindenkinek” gombra. Az új „válasz mindenre” levélben írja be a szavakat a törzsbe. A betűszín biztosan zöld.
• Hasonló módon kattintson a „Tovább” gombra. A továbbító levélben az új szavak kék színnel jelennek meg.

Vegye igénybe a megbízható szoftvert

Abban az esetben Az Outlook korrupciója, Most a felhasználók hajlamosak az Outlook helyreállítási szoftverhez folyamodni. Nagyon sok ilyen program érhető el a piacon. És ezek egy része még ingyenes is. Mindazonáltal óvakodni kell az ismeretlen forrásból származóktól, mert azok tovább ronthatják a jelenlegi esetet. Megbízható és tapasztalt eszközt kell igénybe vennie, mint pl DataNumen Outlook Repair.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sérült sql és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com