Hogyan lehet automatikusan áthelyezni az e-maileket meghatározott CC-címzettekkel az Outlookban

A valóságban a legtöbben egy Outlook-szabály létrehozását remélhetik, amely automatikusan áthelyezi a megadott másolatot kapó címzettekkel rendelkező e-maileket. Az Outlook-szabály azonban nem támogatja a másolatot kapó címzettek ellenőrzését. Ez a cikk tehát megtanítja, hogyan valósíthatja meg ezt az Outlook VBA-val.

Nyilvánvalóan lehetetlen Outlook-szabályt létrehozni bizonyos CC-címzettek kereséséhez. Ahogy a következő képernyőképen látható, a fogadott e-mailek esetében csak azt ellenőrizheti, hogy a saját neve szerepel-e a CC mezőben. Hasonlóképpen, az elküldött e-maileknél még nincs szabályfeltétel a CC négyzet bejelölésére.

Ezért ha azt szeretné beállítani, hogy az Outlook automatikusan áthelyezze az e-maileket bizonyos CC-címzettekkel, más módot kell keresnie. Akkor. itt megtanítjuk, hogyan érheti el ezt az Outlook VBA segítségével.

Az elküldött e-mailek automatikus áthelyezése meghatározott CC-címzettekkel

1. Először lépjen a „Fejlesztő” fülre, és kattintson a „Visual Basic” gombra.
2. Ezután nyissa meg a „ThisOutlookSession” projektet, és másolja be a következő VBA-kódokat.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

3. Ezt követően folytassa a kód aláírásával és a szokásos módon módosítsa a makróbeállításokat.
4. Végül kiléphet a „Visual Basic” ablakból. Ezt követően az adott CC-címzettekkel küldött e-mailek a megadott levélmappába kerülnek.

A fogadott e-mailek automatikus áthelyezése meghatározott CC-címzettekkel

Most, hogy a fenti VBA-kód célja az elküldött e-mailek áthelyezése meghatározott CC-címzettekkel, ha meg szeretne keresni adott CC-címzetteket a fogadott e-mailekben, majd át szeretné helyezni azokat, használja inkább a következő kódokat.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Készüljön fel az Outlook korrupciójára

Bár az Outlook funkciókban gazdag, mégsem lehet immunis a korrupció ellen. Ezért ébernek kell lennie minden lehetséges kockázattal szemben. Kétségtelenül a kritikus lépés az Outlook adatok következetes és naprakész biztonsági mentése. Továbbá meg kell tartania a korrupt Outlook helyreállítási eszköz a közelben. Hasznos lesz, ha a biztonsági mentés és a Scanpst.exe sem sikerül.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve javítás SQL Server mdf fájl hiba és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com