2 módszer több Word-dokumentum gyors egyesítésére VBA-n keresztül

Ebben a cikkben örömmel osztunk meg veled 2 módszert, amellyel gyorsan egyesíthet több Word-dokumentumot VBA-n keresztül.

A Wordben van az alapértelmezett beépített funkció, amely segít a felhasználóknak több dokumentum egyesítésében vagy egyesítésében. A részleteket ebben a cikkben ismertetjük: Több Word dokumentum egyesítése és egyesítése egybe

Ezzel a módszerrel néhány kattintás szükséges, és a következő dokumentum tartalma mindig közvetlenül az előző dokumentuma után érkezik. Ezért szeretnénk Önnek gyorsabb módokat kínálni erre.

1. módszer: egyesítse a kiválasztott dokumentumokat egybe

1. Elsősorban hozz létre egy új, üres dokumentumot.
2. Indítsa el a VBA-szerkesztőt a Wordben az „Alt+F11” megnyomásával.
3. Ezután kattintson a „Normál” gombra.
4. Ezután kattintson a „Beszúrás” gombra.
5. És válassza a „Modul” lehetőséget.
6. Kattintson duplán az új modulra a szerkesztési terület megnyitásához.
7. Illessze be a következő makrót:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Ezután kattintson a „Futtatás” gombra, vagy nyomja meg az „F5” gombot.
9. Most a „Tallózás” ablakban válasszon ki több fájlt a „Ctrl” megnyomásával, majd kattintson az „OK” gombra.
10. Ezután a kiválasztott fájlokban található összes tartalom össze lesz illesztve az új dokumentumban, és minden dokumentum szövege új oldalon kezdődik.

Jegyzet:

Mint említettük, ez a makró minden dokumentum szövegét új oldalra helyezi. De ha szükség van rájuk, hogy egymás után legyenek, módosíthat néhány kódsort a makróban. Csak keresse meg az „If nEachSelectedFile < nTotalFiles Then” sort, törölje azt és a következő hat sort is.

2. módszer: Egyesítse az összes dokumentumot egy mappában

Ha van egy mappája az egyesítendő fájlokból, akkor ez a makró szépen fog működni.

1. A kezdéshez telepítse és futtassa a makrót az 1. módszerben leírtak szerint.
2. Ezután cserélje ki a makrót erre:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Futtassa a makrót a „Futtatás” gombra kattintva.
4. Ezután megjelenik a „Tallózás” ablak. Válassza ki azt a mappát, ahol az összes dokumentumot tárolja. És kattintson az „OK” gombra.

Hasonlóképpen, minden dokumentum szövege új oldalon kezdődik. Ahhoz, hogy egymás után összeillesszék őket, keresd meg és töröld a „.InsertBreak Type:=wdPageBreak” kódsort.

Megfelelően védje Word-dokumentumát

A Word-dokumentumok védelmének egyik legjobb módja az, ha rendszeres biztonsági másolatot készít róluk. Ha a biztonsági mentések a kezében vannak, soha nem kell félnie az adatvesztéstől. Emellett célszerű szerszámot is beszerezni javítás docx ha valamelyik megsérül.

Szerző Bevezetés:

Vera Chen adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sérült Excel és a pdf javító szoftvertermékek. További információért látogasson el www.datanumen.com