2 gyors módszer a megjelölt Outlook e-mailek listájának Excelbe exportálására

Ha szeretné exportálni az összes megjelölt e-mail listáját az Outlook-postafiókból az Excelbe, használhatja a cikkben ismertetett két módszer egyikét.

Például annak érdekében, hogy az összes megjelölt e-mailt időben kezelje, vagy megossza valaki mással, remélheti, hogy exportálja őket egy Excel-munkalapra. Itt bemutatunk 2 megközelítést ennek megvalósításához. Az előbbi a szabványos „Importálás és exportálás” funkciót használja a megjelölt e-mailek megtalálása után. Hogy őszinte legyek, ez egy kicsit unalmas. Így az utóbbiban megtanítunk egy kényelmesebb módszert a VBA alkalmazására.

1. módszer: Az összes talált megjelölt e-mail manuális exportálása

1. Először is kattintson a levelezőlista feletti keresőmezőre.
2. Ezután kattintson az „Összes levéltétel” elemre a „Keresés” lap „Hatókör” csoportjában.
3. Ezután kattintson a „Megjelölt” gombra a „Definiálás” csoportban.
4. A listában szereplő összes megjelölt e-mail után válasszon ki egy e-mailt, és nyomja meg a „Ctrl + A” gombot az összes kijelöléséhez.
5. Ezután nyomja meg a „Ctrl + Shift + V” billentyűparancsokat.
6. Az új párbeszédpanelen hozzon létre egy új mappát az Outlook fájl alatt.
7. Később válassza ki az újonnan létrehozott mappát, és kattintson az „OK” gombra, amely az összes megtalált megjelölt e-mailt áthelyezi az új mappába.
8. Ezután kattintson a „Fájl” > „Megnyitás” > „Importálás” elemre.
9. A felugró párbeszédpanelen válassza az „Exportálás fájlba” > „Következő” > „Microsoft Excel 97-2003” > „Következő” lehetőséget.
10. Az új képernyőn válassza ki a megfelelő mappát, és nyomja meg a „Tovább” gombot.
11. Ezt követően kövesse a varázslókat az „Exportálás” befejezéséhez.
12. Egy új Excel-fájlt fog kapni, amely a következő képernyőképen látható.

2. módszer: Exportálja az összes megjelölt e-mail listáját VBA-n keresztül

1. Az Outlook programban nyomja meg az „Alt + F11” billentyűt a VBA-szerkesztő elindításához.
2. Ezután engedélyezze az „MS Excel Object” elemet a „Hogyan adjunk hozzá egy Object Lib-etrary Hivatkozás a VBA-ban".
3. Ezután másolja be az alábbi VBA-kódot egy modulba.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Végül helyezze a kurzort az „ExportAllFlaggedEmailsToExcel” szubrutinba, és nyomja meg az „F5” gombot.
5. Ezután válasszon ki egy Outlook-fájlt az új párbeszédpanelen.
6. Amikor a „Befejezve” üzenet jelenik meg, egy új Excel-fájlt is kap, mint az alábbi képen.

Védje Outlookját a korrupciótól

Az Outlook hajlamos a hibákra és a korrupcióra, ezért rendkívül nehéz feladat számunkra Outlook adataink védelme. Kétségtelenül a most hatékony és praktikus módszer a rendszeres adatmentések készítése az Outlook számára. Ezen kívül szükségünk van egy hatékony és megbízható Outlook-javító eszközre is, mint pl. DataNumen Outlook Repair. Jól jön, ha postafiók javító eszköz nem gyakorol hatást.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve erősít SQL Server és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com