2 gyors módszer szakaszok kivonására a Word-dokumentumból

Ebben a cikkben 2 gyors és egyszerű módszert kínálunk Önnek a Word-dokumentumból egy másik vagy több szakaszba történő kibontására.

Gyakran előfordul, hogy tartalmat kinyerünk egyik dokumentumból a másikba. Korábbi cikkünkben pedig megbeszéltük, hogyan lehet oldalakat kivonni a dokumentumból. Részletes információkért tekintse meg ezt a cikket: 2 gyors módszer egyes oldalak kivonására a Word-dokumentumból

Ma megmutatjuk, hogyan lehet szakaszonként kivonatolni.    

1. módszer: Az aktuális szakasz kibontása új dokumentumba

1. Először is, pozicionáld a kurzort a célterületre.
2. Ezután nyomja meg az „Alt+F11” gombot a VBA-szerkesztő meghívásához a Wordben.
3. Ezután a bal oldali oszlopban kattintson a „Normál” elemre.
4. És a menüsorban kattintson a "Beszúrás" gombra.
5. Ezután válassza a „Modul” lehetőséget a legördülő menüben.
6. Kattintson duplán az új modul megnyitásához, és illessze be a következő kódokat:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Ezután kattintson a „Futtatás” gombra a menüsorban, vagy nyomja meg az „F5” gombot.
8. Ezután megjelenik a „Tallózás” ablak. Válassza ki az új dokumentum tárolási helyét, és kattintson az „OK” gombra.
9. A „Fájlnév” mezőbe írja be az új fájl nevét, és kattintson az „OK” gombra.

Most kibontotta a részt egy új dokumentumba.

2. módszer: A dokumentum minden egyes szakaszának kibontása egyedi új részekhez

Ez a módszer segíthet a dokumentum összes szakaszának kötegelt feldolgozásában. Természetesen szükségünk lesz makróra is.

1. Először is nyisd meg a céldokumentumot.
2. Ezután kövesse az 1. módszer lépéseit a makró telepítéséhez és futtatásához.
3. Csak ezúttal cserélje ki ezt a makrót erre:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Ennek ellenére a „Tallózás” ablakban válassza ki a tárolási útvonalat, és kattintson az „OK” gombra.

Javítsa ki az irritáló szóhibákat

Használata során gyakran találkozhatunk Word-hibákkal. Lehet, hogy bosszantó, időt kell szánnunk rá szó visszaszerzése a lehető leghamarabb. Mert minél tovább késleltetjük, annál súlyosabb lehet az adatvesztés. Ezért azt javasoljuk, hogy előzetesen szerezzen be egy javító segédprogramot.

Szerző Bevezetés:

Vera Chen adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sérült xls és a pdf javító szoftvertermékek. További információért látogasson el www.datanumen.com