Comment utiliser automatiquement différentes couleurs de police pour répondre et transférer des e-mails avec Outlook VBA

Par défaut, vous ne pouvez pas laisser Outlook utiliser automatiquement différentes couleurs de police pour répondre et transférer des e-mails. Par conséquent, si vous avez une telle exigence, vous pouvez lire ce post pour apprendre une approche intelligente.

Outlook vous permet uniquement de spécifier une police utilisée à la fois pour répondre et transférer des e-mails. Vous pouvez aller dans "Fichier" > "Options". Ensuite, dans "Outlook Options", accédez à l'onglet "Mail" et cliquez sur le bouton "Papeterie et polices ...". Dans la fenêtre suivante, vous pouvez voir le bouton "Police" dans "Répondre ou transférer des messages". Cliquez dessus, puis vous pourrez définir une couleur de police spécifique pour répondre et transférer des e-mails.

Cependant, de nombreux utilisateurs espèrent utiliser différentes couleurs de police pour répondre ou transférer des e-mails. Bien qu'Outlook ne fournisse aucune fonctionnalité directe pour cela, il peut toujours être réalisé avec du code VBA. Maintenant, lisez la suite pour obtenir un tel morceau de code VBA.

Utiliser automatiquement différentes couleurs de police pour répondre et transférer des e-mails

1. Pour commetart, lancez l'application Outlook.
2. Ensuite, lancez l'éditeur VBA en faisant référence à "Comment exécuter le code VBA dans votre Outlook" .
3. Ensuite, conformément à "Comment ajouter une bibliothèque d'objetsrary Référence dans VBA», ajoutez la référence à « MS Word Object Library ».
4. Ensuite, copiez le code suivant dans le projet "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Après cela, restart Outlook pour activer cette macro.
6. Enfin, vous pouvez essayer.

• Sélectionnez ou ouvrez un e-mail.
• Ensuite, cliquez sur le bouton "Répondre". En répondant à un e-mail, vous pouvez taper quelques mots dans le corps. La couleur de la police doit être rose.
• Ou cliquez sur le bouton "Répondre à tous". Dans le nouveau courrier "répondre à tous", saisissez des mots dans le corps. La couleur de la police est sûrement verte.
• De même, cliquez sur le bouton "Suivant". Dans le courrier de transfert, les nouveaux mots seront affichés en bleu.

Recourir à un logiciel fiable

Dans le cas où Corruption d'Outlookmost les utilisateurs ont tendance à recourir au logiciel de récupération Outlook. Il existe une grande quantité de ces programmes disponibles sur le marché. Et certains d'entre eux sont même gratuits. Néanmoins, vous devez vous méfier de ceux provenant de sources inconnues dans la mesure où ils peuvent aggraver de plus en plus le cas actuel. Vous devez vous aider d'un outil fiable et expérimenté, comme DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris sql corrompu et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com