Comment exporter la structure des dossiers de votre fichier Outlook vers Excel

Si vous souhaitez exporter rapidement la structure de dossiers de votre fichier de données Outlook vers un classeur Excel, vous pouvez utiliser la méthode présentée dans cet article.

Pour certaines raisons, telles que la journalisation des dossiers et sous-dossiers Outlook actuels, de nombreux utilisateurs espèrent exporter la structure de dossiers d'un fichier Outlook vers un fichier externe, comme un classeur Excel. Dans ce qui suit, nous vous partagerons un morceau de code VBA, qui peut vous aider à le réaliser en un tournemain.

Exporter la structure de dossiers de votre fichier Outlook vers Excel

1. À start avec, lancez votre application Outlook.
2. Ensuite, dans la fenêtre principale d'Outlook, appuyez sur les touches "Alt + F11".
3. Ensuite, vous entrerez dans l'éditeur Outlook VBA, dans lequel vous devez ouvrir un module inutilisé.
4. Ensuite, vous pouvez copier le code VBA suivant dans ce module.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

5. Après cela, vous devez vous assurer qu'Outlook a activé les macros.
6. Finalement, vous pouvez prendre une photo :

• Dans la fenêtre de macro actuelle, appuyez sur la touche F5.
• Une fois la macro terminée, vous recevrez une alerte indiquant "Terminé".
• Plus tard, vous pouvez vous diriger vers le dossier local prédéfini pour trouver un nouveau fichier Excel. Ouvrez-le et il ressemblera à la capture d'écran suivante :

Ne négligez jamais les erreurs Outlook

Malgré des quantités de fonctionnalités, Outlook est le même sensible aux erreurs et à la corruption que les autres clients de messagerie. Par conséquent, vous devez attacher de l'importance à toutes les erreurs dans votre Outlook. Ne les négligez pas, s'il vous plaît. Sinon, l'accumulation d'erreurs peut finalement entraîner la corruption d'Outlook. Si vous êtes confronté à des erreurs noueuses, il est suggéré d'utiliser un outil puissant, tel que DataNumen Outlook Repair, Qui peut réparer Outlook erreurs en quelques secondes.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris récupération SQL et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com