Comment dézipper le .Zip Pièces jointes directement dans Outlook via VBA

Lorsque vous recevez une pièce jointe dans «.zipSi vous souhaitez décompresser des fichiers .txt, il est généralement conseillé de les enregistrer et de les extraire sur votre disque dur. Cependant, beaucoup souhaitent les décompresser directement dans Outlook. Cet article vous explique comment procéder via VBA.

Vous avez sûrement déjà reçu les pièces jointes qui se trouvent dans «.zip" extension de fichier. Afin d'accéder aux fichiers internes en un seul zip Pour ouvrir le fichier, vous devez d'abord le décompresser. Dans ce cas, comme d'habitude, vous devez d'abord enregistrer le fichier. zip Copiez le fichier sur votre disque dur, puis faites un clic droit dessus et sélectionnez « Extraire tout » dans le menu contextuel. En pratique, de nombreux utilisateurs préfèrent décompresser le fichier directement dans Outlook. Cependant, Outlook ne propose pas cette fonctionnalité nativement. Heureusement, vous pouvez suivre les étapes ci-dessous pour utiliser VBA et réaliser cette opération très facilement.

Décompressez le .Zip Pièces jointes directement dans Outlook

1. En premier lieu, lancez votre application Outlook.
2. Appuyez ensuite sur le raccourci clavier "Alt + F11" dans la fenêtre Outlook pour accéder à l'éditeur VBA.
3. Ensuite, dans la fenêtre "Microsoft Visual Basic pour Applications", ouvrez un module qui n'est pas utilisé.
4. Ensuite, copiez et collez les codes VBA suivants dans ce module.

Public Sub UnzipFileInOutlook()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objShell As Object
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim strFileName As String
 
    Set objMail = Outlook.Application.ActiveInspector.CurrentItem
    Set objAttachments = objMail.attachments
 
    'Save & Unzip the zip file in local drive
    Set objShell = CreateObject("Shell.Application")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "yyyy-mm-dd-hh-mm-ss")
    MkDir (strTempFolder)
 
    For Each objAttachment In objAttachments
        If Right(objAttachment.FileName, 3) = "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.FileName
           objAttachment.SaveAsFile (strFilePath)
           objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strFilePath)).Items
        End If
    Next
 
    'Reattach the files extracted from the zip file
    strFileName = Dir(strTempFolder & "\")
 
    While Len(strFileName) > 0
          objMail.attachments.Add (strTempFolder & "\" & strFileName)
          strFileName = Dir
          objMail.Save
    Wend
 
    'Delete the attachments in “.zip” file extension
    Set objAttachments = objMail.attachments
    For Each objAttachment In objAttachments
        If Right(objAttachment.FileName, 3) = "zip" Then
           objAttachment.Delete
           objMail.Save
        End If
    Next
 
    'Delete the temp folder and files
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Après cela, vous pouvez ajouter le nouveau projet VBA à la barre d'outils d'accès rapide de la fenêtre de message comme d'habitude.
6. Enfin, vous pouvez essayer.

• Tout d'abord, ouvrez un message avec zip fichier dans sa propre fenêtre.
• Cliquez ensuite sur "Actions" > "Modifier le message".
• Cliquez ensuite sur le bouton Nouvelle macro dans la barre d'outils d'accès rapide.
• D'un coup, le zip Le fichier sera décompressé, comme le montre la capture d'écran suivante :

Débarrassez-vous des problèmes PST ennuyeux

Bien que le fichier PST au nouveau format Unicode prenne en charge une taille de fichier de 20 Go, il est toujours sage de garder le fichier aussi petit que possible. C'est parce qu'un gros fichier PST est beaucoup plus sujet à la corruption. Une fois que votre fichier PST est compromis, vous devrez faire des efforts pour récupérer PST données. Dans ce scénario, vous n'avez pas d'autre choix que de recourir à un outil éprouvé et réputé comme DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris réparation sql et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com