Comment imprimer rapidement tous les fichiers d'un Zip Pièce jointe d'un e-mail Outlook

De nombreux utilisateurs espèrent imprimer tous les fichiers compressés dans un zip pièce jointe d'un e-mail Outlook sans enregistrer et décompresser péniblement le zip pièce jointe. Par conséquent, cet article présentera un moyen beaucoup plus efficace de le réaliser.

Lorsque vous voulez imprimer un zip Si vous avez l'habitude d'ajouter une pièce jointe et de cliquer sur le bouton « Impression rapide » du ruban, Outlook vous demandera tout de même de l'enregistrer et de la décompresser au préalable. Pour éviter ces étapes fastidieuses, vous pouvez utiliser le code VBA suivant.

Imprimer tous les fichiers d'un Zip Pièce jointe d'un e-mail

1. Pour commencer, ouvrez votre application Outlook.
2. Ensuite, accédez à l'éditeur Outlook VBA en suivant les étapes indiquées dans l'article - "Comment exécuter le code VBA dans votre Outlook ».
3. Ensuite, vous pouvez ouvrir le projet "ThisOutlookSession" ou un module inutilisé.
4. Ensuite, copiez et collez le code VBA ci-dessous.

Dim objShell As Object
Dim objFileSystem As Object

Sub PrintAllFilesInZipAttachment ()
    Dim objAttachmentSelection As Outlook.AttachmentSelection
    Dim objAttachment, objTempAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim strSavingPath As String
    Dim objTempMail As Outlook.MailItem
    Dim strFileName As String
 
    'Get selected attachment
    Set objAttachmentSelection = Outlook.Application.ActiveExplorer.AttachmentSelection
    Set objAttachment = objAttachmentSelection.Item(1)

    If Right(LCase(objAttachment.filename), 3) = "zip" Then
 
       'Save & Unzip the zip attachment
       Set objShell = CreateObject("Shell.Application")
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Unzip" & Format(Now, "yyyymmddhhmmss")
       MkDir (strTempFolder)
 
       strSavingPath = strTempFolder & "\" & objAttachment.filename
       objAttachment.SaveAsFile (strSavingPath)
       objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strSavingPath)).Items
  
       'Attach Unzipped files to a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       strFileName = Dir(strTempFolder & "\")
 
       While Len(strFileName) > 0
             objTempMail.Attachments.Add (strTempFolder & "\" & strFileName)
             strFileName = Dir()
       Wend
 
       'Print all attachments of the temp email
       Call PrintFiles(objTempMail)
 
       objTempMail.Close olDiscard
 
       objFileSystem.DeleteFolder (strTempFolder)
    End If
End Sub

Sub PrintFiles(ByVal objMail As Outlook.MailItem)
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder, strFilePath As String
    Dim objTempFolder As Object
    Dim objTempFolderItem As Object
 
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\TEMP" & Format(Now, "yyyymmddhhmmss")
    MkDir (strTempFolder)
 
    'Print all attachments
    For Each objAttachment In objMail.Attachments
        If Right(LCase(objAttachment.filename), 3) <> "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile (strFilePath)
 
           Set objShell = CreateObject("Shell.Application")
           Set objTempFolder = objShell.NameSpace(0)
           Set objTempFolderItem = objTempFolder.ParseName(strFilePath)
           objTempFolderItem.InvokeVerbEx ("print")
        End If
    Next
 
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Après cela, fermez la fenêtre actuelle de l'éditeur VBA.
6. Plus tard, dirigez-vous vers les options Outlook pour ajouter la nouvelle macro à la barre d'outils d'accès rapide.
7. Enfin, vous pouvez prendre une photo :

• Tout d'abord, sélectionnez un zip pièce jointe d'un e-mail.
• Ensuite, cliquez sur la macro dans la barre d'outils d'accès rapide.

8. Aussitôt, les fichiers se compressent dans le zip la pièce jointe sera imprimée.

Sauvegarder les fichiers de données Outlook

Vous avez peut-être constaté qu'Outlook est sujet à la corruption. Une fois Outlook corrompu, vos données sont perdues. Il est donc important d'effectuer régulièrement des sauvegardes de vos fichiers de données Outlook afin de pouvoir facilement les récupérer. Cependant, si votre sauvegarde date de plusieurs semaines et est devenue inefficace, vous n'aurez d'autre choix que de faire appel à un prestataire fiable et expérimenté. Récupération PST outil, tel que DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris mdf endommagé et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com