Comment fusionner et exporter rapidement plusieurs pièces jointes de classeur Excel dans un seul classeur dans Outlook

Lorsque vous recevez un e-mail joint à plusieurs classeurs Excel, si vous souhaitez vérifier le contenu de tous les classeurs dans un seul classeur, vous pouvez utiliser la méthode décrite dans cet article. Il exportera plusieurs pièces jointes de classeur Excel vers un seul classeur.

Pour afficher toutes les pièces jointes Excel d'un e-mail dans un seul classeur Excel, vous devez d'abord les combiner et les exporter dans un seul classeur. Au lieu de le faire manuellement, vous pouvez utiliser la méthode suivante pour y parvenir facilement. Elle vous apprendra à utiliser le code VBA. Pour savoir comment utiliser VBA, vous pouvez consulter l'article « Comment exécuter le code VBA dans votre Outlook ».

Fusionner et exporter plusieurs pièces jointes de classeur Excel dans un seul classeur

1. Pour commencer, lancez votre application Outlook.
2. Ensuite, accédez à l'éditeur Outlook VBA.
3. Ensuite, dans la nouvelle fenêtre « Microsoft Visual Basic pour Applications », vous devez activer « Bibliothèque d’objets MS Excel », à propos de laquelle vous pouvez vous référer à l’article : « Comment ajouter une référence à une bibliothèque d'objets en VBA ».
4. Ensuite, copiez le code VBA suivant dans un projet ou un module.

Sub CombineMultipleExcelWorkbookAttachmensIntoOne()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim strFile As String
    Dim objCurrentSheet As Excel.Worksheet
    Dim objCurrentBook As Excel.Workbook
    Dim objSheet As Excel.Worksheet
    Dim objFileSystem As Object
 
    On Error Resume Next
    'Create a new temp folder
    strTempFolder = "E:\Temp" & Format(Now, "yyymmddhhmmss") & "\"
    MkDir (strTempFolder)
 
    'Save selected attachments
    Set objSelectedAttachments = Outlook.Application.ActiveExplorer.AttachmentSelection
    For Each objAttachment In objSelectedAttachments
        objAttachment.SaveAsFile (strTempFolder & objAttachment.FileName)
    Next
 
    'Copy all the workbooks into a new file
    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelWorkbook.Activate
 
    strFile = Dir(strTempFolder)
    Do While strFile <> ""
       Set objCurrentBook = objExcelApp.Workbooks.Open(strTempFolder & strFile)
       For Each objCurrentSheet In objCurrentBook.Sheets
           objCurrentSheet.Copy Before:=objExcelWorkbook.Sheets(1)
       Next
 
       objExcelApp.Workbooks(strFile).Close
       strFile = Dir()
    Loop
 
    'Remove empty sheets
    objExcelApp.DisplayAlerts = False
    For Each objSheet In objExcelWorkbook.Worksheets
        If objExcelApp.WorksheetFunction.CountA(objSheet.Cells) = 0 Then
           objSheet.Delete
        End If
    Next
    objExcelApp.DisplayAlerts = True
 
    'Delete the temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Après cela, vous pouvez fermer la fenêtre et ajouter la nouvelle macro à la barre d'outils d'accès rapide.
6. Plus tard, indiquez l'e-mail source dans la liste de diffusion.
7. Ensuite, maintenez la touche "Ctrl" enfoncée pour sélectionner les pièces jointes du classeur Excel que vous souhaitez exporter.
8. Ensuite, cliquez sur le bouton macro dans la barre d'outils d'accès rapide.
9. Une fois la macro terminée, un nouveau classeur Excel s'affiche. Il contiendra le contenu des classeurs Excel précédemment sélectionnés.

Ayez recours à un outil de réparation externe plus puissant

Lorsqu'ils rencontrent des problèmes de corruption d'Outlook, la plupart des utilisateurs auront tendance à utiliser… outil de réparation de boîte de réception pour essayer en premier lieu. Cependant, cela ne sera pas d'une grande aide en cas de dommages graves. À ce stade, vous n'avez d'autre choix que de vous aider d'un outil externe fiable et expérimenté, tel que DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris récupération mdf et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com