Comment insérer rapidement les noms des destinataires dans le corps de l'e-mail dans votre Outlook

Si vous souhaitez insérer rapidement les noms des destinataires dans le corps lors de la rédaction d'un e-mail, vous pouvez lire cet article. Ici, nous allons vous présenter une méthode pratique.

Parfois, vous devrez peut-être saisir les noms de tous les destinataires dans le corps lorsque vous composez un e-mail. Sans aucun doute, il est considérablement fastidieux et fastidieux d'extraire et d'insérer manuellement les noms dans le corps un par un. Par conséquent, afin de vous aider à l'accomplir rapidement, nous allons vous partager ici un moyen efficace. Lisez la suite pour obtenir ses étapes détaillées.

Insérer les noms des destinataires dans le corps de l'e-mail

1. Pour commencer, accédez à l'éditeur VBA via « Alt + F11 ».
2. Ensuite, dans la fenêtre « Microsoft Visual Basic pour Applications », activez « Bibliothèque d’objets MS Word » conformément à « Comment ajouter une référence à une bibliothèque d'objets en VBA" .
3. Ensuite, copiez le code VBA ci-dessous dans un module vide.

Sub CopyRecipientNamesToBody()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim strRecipAddress As String
    Dim strRecipName As String
    Dim objContacts As Outlook.Items
    Dim i As Integer
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim strRecipNames As String
    Dim objMailDocument As Word.Document
 
    'Get the current email
    Set objMail = Application.ActiveInspector.CurrentItem
    objMail.Recipients.ResolveAll
 
    For Each objRecipient In objMail.Recipients
        strRecipAddress = objRecipient.Address
 
        'Get the corresponding contact name
        Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
        For i = 1 To 3
            strFilter = "[Email" & i & "Address] = " & strRecipAddress
            Set objFoundContact = objContacts.Find(strFilter)
            If Not (objFoundContact Is Nothing) Then
               strRecipNames = strRecipNames & objFoundContact.FullName & vbCr
               Exit For
            End If
        Next
 
        'If there isn't associated contact
        'Extract name from email address
        If objFoundContact Is Nothing Then
           strRecipName = Split(strRecipAddress, "@")(0)
           strRecipName = UCase(Left(strRecipName, 1)) & Right(strRecipName, Len(strRecipName) - 1)
           strRecipNames = strRecipNames & strRecipName & vbCr
        End If
    Next
 
    'Insert the names at the beginning of email
    Set objMailDocument = objMail.GetInspector.WordEditor
    objMailDocument.Range(0, 0).InsertAfter strRecipNames
End Sub

3. Ensuite, ajoutez cette macro à la barre d'outils d'accès rapide de la fenêtre Message selon l'étape facultative dans "Comment exécuter le code VBA dans votre Outlook" .
4. Après cela, quittez la fenêtre.
5. Enfin, prenez une photo.

• Tout d'abord, composez un e-mail et remplissez les destinataires.
• Ensuite, appuyez sur le bouton macro dans la barre d'outils d'accès rapide.
• Lorsque la macro se termine, les noms des destinataires ont été insérés dans le corps de l'e-mail, comme indiqué dans la figure ci-dessous.

Protégez-vous contre les dommages d'Outlook

Étant donné qu'Outlook est vulnérable, il est difficile de protéger Outlook contre les dommages. Sans aucun doute, vous devez être réticent à rencontrer Fichier PST corrompu. Par conséquent, vous feriez mieux de prendre quelques précautions efficaces. Par exemple, vous devez effectuer des sauvegardes de données cohérentes pour Outlook, vous familiariser avec l'utilisation de l'outil de réparation de la boîte de réception et conserver un puissant outil externe à proximité, tel que DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris SQL Server fixer et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com