Comment exporter rapidement le temps total passé sur les rendez-vous Outlook dans chaque catégorie de couleur

Si vous souhaitez créer un rapport sur le temps total que vous passez sur les rendez-vous dans chaque catégorie de couleur, vous pouvez utiliser la méthode présentée dans cet article. Cela peut vous aider à accomplir cela rapidement sans avoir besoin de compter manuellement.

De nombreux utilisateurs ont l'habitude d'enregistrer la plupart de leurs activités dans leur calendrier Outlook. Afin de les gérer et de les différencier plus facilement, ils leur attribuent des catégories. Certains souhaitent générer un rapport indiquant le temps total passé sur les éléments du calendrier dans chaque catégorie de couleur. Saisir et compter ces données manuellement est fastidieux. C'est pourquoi nous vous proposons ici une méthode permettant d'effectuer cette tâche en un seul clic.

Exporter le temps total passé sur les rendez-vous dans chaque catégorie de couleur

1. En premier lieu, lancez votre application Outlook.
2. Ensuite, après être entré dans la fenêtre Outlook, vous pouvez appuyer sur les touches "Alt + F11".
3. Par la suite, vous aurez accès à la fenêtre « Microsoft Visual Basic pour Applications ».
4. Ensuite, vous devrez activer la « Bibliothèque d'objets Microsoft Excel ». Pour ce faire, cliquez sur « Outils » > « Référence ».
5. Ensuite, vous devez trouver et ouvrir un module qui n'est pas utilisé.
6. Après cela, vous devez copier le code VBA suivant dans ce module.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Enfin, vous pouvez déclencher cette macro, peu importe en cliquant sur l'icône "Exécuter" dans la barre d'outils ou en appuyant sur la touche "F5".
8. Ensuite, il vous sera demandé de sélectionner un calendrier spécifique.
9. Après avoir sélectionné et cliqué sur "OK", la macro continuera à s'exécuter. Une fois terminé, un nouveau fichier Excel s'affichera en arrière-plan.
10. Vous pouvez y accéder. Cela ressemblera à la capture d'écran suivante :

Gardez un œil sur les menaces potentielles autour de votre Outlook

Les utilisateurs d'Outlook doivent faire attention à tous les risques potentiels, y compris les pièces jointes inconnues, les liens intégrés et les erreurs humaines. Sinon, votre Outlook peut être corrompu à tout moment. De plus, effectuer des sauvegardes régulières des données Outlook et conserver un outil de réparation spécialisé est une nécessité. DataNumen Outlook Repair est l'un des outils de réparation les plus recommandés. Il peut réparer Outlook problèmes en un tour de main.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris mdf endommagé et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com