Comment exporter rapidement tous les dossiers et éléments Outlook de la section "Favoris" vers un dossier Windows

Si vous souhaitez exporter tous les dossiers Outlook ainsi que ses éléments dans la section "Favoris", vous pouvez vous référer à cet article. Ici, nous allons vous montrer comment l'accomplir en un temps record.

Généralement, les dossiers et leurs éléments dans la section "Favoris" sont d'une grande importance et fréquemment nécessaires. Par conséquent, vous voudrez peut-être parfois les exporter vers le lecteur local. De manière standard, vous devez créer des dossiers Windows selon les dossiers dans "Favoris" et enregistrer les éléments en tant que fichiers MSG un par un dans le lecteur local. C'est trop fastidieux. Par conséquent, nous allons exposer ici un moyen beaucoup plus efficace. Maintenant, lisez la suite pour l'obtenir.

Exporter tous les dossiers et éléments de la section "Favoris" vers un dossier Windows

1. Pour commencer, accédez à l'éditeur VBA dans Outlook en vous référant à "Comment exécuter le code VBA dans votre Outlook" .
2. Ensuite, copiez le code suivant dans un module vide.

Sub ExportAllFoldersItems_InFavorites_ToWindowsFolder()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFileSystem As Object
    Dim strWindowsFolder As String
    Dim objNavigationPane As Outlook.NavigationPane
    Dim objNavigationModule As Outlook.NavigationModule
    Dim objNavigationGroup As Outlook.NavigationGroup
    Dim objNavigationFolder As Outlook.NavigationFolder
    Dim objFolder As Outlook.Folder
    Dim strFolderPath As String
    Dim objItem As Object
    Dim strFilePath As String
    Dim i As Long
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
     
       'Get "Favorites" section
       Set objNavigationPane = Application.ActiveExplorer.NavigationPane
       Set objNavigationModule = objNavigationPane.Modules.GetNavigationModule(olModuleMail)
       Set objNavigationGroup = objNavigationModule.NavigationGroups.GetDefaultNavigationGroup(olFavoriteFoldersGroup)
 
       'Export the folders and items in "Favorites" section
       For Each objNavigationFolder In objNavigationGroup.NavigationFolders
           Set objFolder = objNavigationFolder.Folder
           strFolderPath = strWindowsFolder & objFolder.Name
           objFileSystem.CreateFolder strFolderPath
 
           For Each objItem In objFolder.Items
               strSubject = objItem.Subject
               strFileName = strSubject & ".msg"
 
               i = 0
               Do Until False
                  strFilePath = strFolderPath & "\" & strFileName
                  If objFileSystem.FileExists(strFilePath) Then
                     i = i + 1
                     strFileName = strSubject & " (" & i & ").msg"
                  Else
                     Exit Do
                  End If
               Loop
 
               objItem.SaveAs strFilePath, olMSG
          Next
       Next
 
       'Open the Windows folder
       Call Shell("explorer.exe " & strWindowsFolder, vbNormalFocus)
    End If
End Sub

3. Ensuite, cliquez sur l'icône "Exécuter" dans la barre d'outils.
4. Ensuite, dans la boîte de dialogue contextuelle, sélectionnez un dossier Windows de destination et cliquez sur "OK".
5. Une fois la macro terminée, le dossier Windows s'affiche.
6. Dans ce dossier Windows, les dossiers et ses éléments dans la section "Favoris" ont été exportés, comme la capture d'écran suivante.

Restaurer les données Outlook à partir des sauvegardes

Il est fortement recommandé de sauvegarder régulièrement les fichiers Outlook. C'est parce que si vous souffrez de corruption de fichiers Outlook, vous pouvez récupérer Outlook facilement les données des sauvegardes. Mais, si vous n'avez pas une telle sauvegarde, vous devez essayer une solution Outlook ardue. À ce moment-là, l'outil de réparation de la boîte de réception ne sera pas d'une grande aide. Vous devez prendre l'aide d'un outil externe fixe, tel que DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris sql corrompu et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com