Comment exporter rapidement les détails de tous les membres d'un groupe de contacts Outlook vers Excel

Par défaut, vous ne pouvez voir que les noms et adresses e-mail des membres d'un groupe de contacts. Si vous souhaitez obtenir les autres détails des membres, vous pouvez utiliser la méthode présentée dans cet article.

Lorsque vous double-cliquez sur un groupe de contacts pour l'ouvrir, dans sa fenêtre, vous ne pouvez voir que les noms et adresses e-mail des membres du groupe. Vous ne pouvez pas obtenir les autres détails des membres, comme la société, le titre du poste, le numéro de téléphone ou l'adresse professionnelle, etc. En général, pour obtenir ces détails, vous devez rechercher manuellement les contacts correspondant aux membres dans votre dossier Contacts. C'est trop gênant. Ici, nous allons vous montrer un morceau de code VBA, qui peut rapidement exporter ces détails vers un classeur Excel.

Exporter les détails de tous les membres d'un groupe de contacts vers Excel

1. Pour commencer, lancez votre application Outlook.
2. Ensuite, vous devez appuyer sur les raccourcis clavier "Alt + F11" dans la fenêtre principale d'Outlook.
3. Ensuite, dans la nouvelle fenêtre "Microsoft Visual Basic pour Applications", vous devez ouvrir un module non utilisé ou insérer directement un nouveau module.
4. Ensuite, copiez et collez le code VBA suivant dans ce module.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Après cela, pour une vérification pratique, vous pouvez ajouter le nouveau projet VBA à la barre d'outils ou au ruban d'accès rapide.
6. Définissez ensuite le niveau de sécurité de votre macro Outlook sur faible.
7. En fin de compte, vous pouvez essayer.

• Tout d'abord, sélectionnez un groupe de contacts.
• Appuyez ensuite sur le bouton macro dans la barre d'outils d'accès rapide ou le ruban.
• Immédiatement, la macro s'exécutera.
• Une fois terminé, vous obtiendrez une invite de "Terminé!"
• Après cela, vous pouvez accéder au dossier local de destination prédéfini, dans lequel vous pouvez trouver un nouveau fichier Excel.
• Ouvrez-le, vous verrez les coordonnées des membres du groupe comme la capture d'écran suivante :

Ne paniquez pas face aux problèmes d'Outlook

Personne n'est prêt à accepter les problèmes d'Outlook, peu importe le message d'erreur contextuel ou Outlook corrompu fichier de données. Par conséquent, les utilisateurs auront tendance à paniquer lorsqu'ils rencontreront des problèmes Outlook. Si vous voulez garder votre calme dans ce cas, vous devez avoir deux nécessités en main. L'un est les sauvegardes de données Outlook actuelles. L'autre est un puissant logiciel de correction d'Outlook, comme DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris récupération SQL et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com