Comment convertir rapidement toutes les images intégrées en pièces jointes dans votre e-mail Outlook

Si vous souhaitez modifier rapidement toutes les images intégrées dans le corps du message en pièces jointes, vous n'avez pas besoin de les supprimer et de les rattacher manuellement. Vous pouvez simplement utiliser le morceau de code VBA exposé dans cet article.

Parfois, vous souhaiterez peut-être transformer par lots toutes les images intégrées en pièces jointes. Par exemple, trop d'images dans le corps du message interrompront votre lecture des textes dans le corps. Par conséquent, vous souhaitez les supprimer du corps de l'e-mail et les ajouter en tant que pièces jointes à la place. Bien sûr, vous pouvez le faire manuellement. Mais il doit être plus pratique si des outils ou des codes VBA peuvent obtenir cela en une seule fois. Ici, nous allons vous dévoiler un tel code VBA.

Convertissez rapidement toutes les images intégrées en pièces jointes

1. Pour commencer, ouvrez votre programme Outlook.
2. Ensuite, vous pouvez passer à l'onglet "Développeur" et appuyer sur le bouton "Visual Basic".
3. Ensuite, vous entrerez dans la fenêtre de l'éditeur Outlook VBA.
4. Ensuite, vous devez copier le code VBA suivant dans un module vide.

Sub TurnEmebeddedImagestoAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFile As String
    Dim i As Long
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = Application.ActiveExplorer.Selection.Item(1)
    End Select

    Set objAttachments = objMail.attachments
 
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    MkDir (strTempFolder)
 
    'Save all embedded images to temp folder
    For i = objAttachments.Count To 1 Step -1
        Set objAttachment = objAttachments.Item(i)
        If IsEmbedded(objAttachment) = True Then
           objAttachment.SaveAsFile strTempFolder & "\" & objAttachment.FileName
        End If
    Next
 
    'Add extracted images as attachments
    strTempFolder = strTempFolder & "\"
    strFile = Dir(strTempFolder)
 
    While Len(strFile) > 0
          objMail.attachments.Add (strTempFolder & strFile)
          strFile = Dir
    Wend
 
    'Remove embedded images from message body
    With objMail
        .BodyFormat = olFormatPlain
    End With
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Après cela, vous devez confirmer que votre Outlook est configuré pour autoriser les macros.
6. En option, si vous en avez fréquemment besoin, vous feriez mieux d'ajouter la nouvelle macro à la barre d'outils d'accès rapide pour une future vérification pratique.
7. Finalement, vous pouvez essayer. Sélectionnez ou ouvrez un e-mail, puis exécutez la macro en cliquant sur le bouton Nouvelle macro dans la barre d'outils d'accès rapide.
8. Immédiatement, toutes les images intégrées seront remplacées par des pièces jointes comme la capture d'écran suivante :

Astuces pour protéger vos précieuses données Outlook

Comme nous le savons tous, le fichier Outlook PST est le même vulnérable que les fichiers courants, tels que les documents Word ou les feuilles de calcul Excel. Par conséquent, vous devez continuer à surveiller tous les risques liés à votre fichier PST, tels que les virus ou les manipulations inappropriées. Vous devez donc effectuer des sauvegardes de données régulières pour votre fichier PST. De plus, si vous pouvez vous le permettre, il est sage de garder un solide Réparation Outlook outil pratique, comme DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris récupérer mdf et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com