Comment joindre rapidement le dernier fichier modifié d'un dossier Windows à votre courrier électronique Outlook

Parfois, vous souhaiterez peut-être rechercher et joindre rapidement le dernier fichier modifié dans un dossier Windows spécifique à un e-mail Outlook. Dans ce cas, vous pouvez utiliser la méthode présentée dans cet article.

Certains utilisateurs souhaitent qu'Outlook détecte et ajoute automatiquement à un e-mail le dernier fichier modifié dans un dossier Windows, c'est-à-dire le fichier le plus récemment créé, modifié ou enregistré. Cependant, Outlook ne propose pas cette fonctionnalité nativement. C'est pourquoi nous présentons ci-dessous un extrait de code VBA permettant de réaliser cette opération facilement.

Joindre le dernier fichier modifié d'un dossier Windows à un e-mail

1. Au tout début, vous devez lancer votre application Outlook.
2. Ensuite, après être entré dans la fenêtre principale d'Outlook, vous pouvez appuyer sur les touches "Alt + F11".
3. Ensuite, vous accéderez à la fenêtre de l'éditeur Outlook VBA avec succès.
4. Ensuite, vous devez trouver et ouvrir un module qui n'est pas utilisé.
5. Ensuite, copiez et collez le code VBA suivant dans cette fenêtre de module.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Après cela, vous pouvez quitter la fenêtre actuelle de l'éditeur VBA et ajouter la nouvelle macro à la barre d'outils d'accès rapide ou au ruban de la fenêtre de message.
7. Plus tard, vous devrez modifier le niveau de sécurité de votre macro Outlook sur faible.
8. Finalement, vous pouvez essayer.

• Tout d'abord, créez et composez un nouvel e-mail Outlook comme d'habitude.
• Cliquez ensuite sur le bouton macro dans la barre d'outils d'accès rapide, comme dans l'image ci-dessous :
• Ensuite, vous devrez sélectionner un dossier Windows source et cliquer sur "OK".
• S'il existe un tel fichier dans le dossier Windows sélectionné, vous obtiendrez une invite semblable à la capture d'écran suivante :
• Lorsque vous cliquez sur "Oui", ce fichier sera joint immédiatement.

Résoudre les problèmes Outlook dès que possible

Chaque fois que vous rencontrez des problèmes Outlook, il est recommandé de les résoudre dès que possible. Dans cette situation, vous feriez mieux de préparer un solide Correctif Outlook outil à l'avance, comme DataNumen Outlook Repair. Il est capable de corriger les erreurs PST et de sauver efficacement vos données Outlook.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris mdf corrompu et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com