Comment ouvrir par lots tous les hyperliens avec un domaine spécifique dans votre e-mail Outlook

Lors de la visualisation d'un e-mail Outlook contenant de nombreux hyperliens dans le corps, vous souhaiterez peut-être parfois ouvrir rapidement les hyperliens avec un domaine spécifique. Ici, nous allons partager une méthode pour ouvrir ces hyperliens en masse.

Face à plusieurs hyperliens dans un e-mail, vous pouvez espérer vérifier certains d'entre eux, au lieu de tous. Par exemple, vous souhaitez uniquement ouvrir par lots les hyperliens avec un domaine spécifique. En général, il faut cliquer un par un pour les ouvrir. C'est très gênant. Par conséquent, dans ce qui suit, nous vous apprendrons un moyen plus pratique.

Ouvrir par lots tous les hyperliens avec un domaine spécifique dans un e-mail

1. Pour commetart, accédez à l'éditeur Outlook VBA selon "Comment exécuter le code VBA dans votre Outlook" .
2. Ensuite, dans la fenêtre "Microsoft Visual Basic pour Applications", activez la référence à "MS Word Object Library » en référence à «Comment ajouter une bibliothèque d'objetsrary Référence dans VBA" .
3. Ensuite, copiez le code VBA suivant dans un module ou un projet inutilisé.

Sub BatchOpenHyperlinksWithSpecificDomain()
    Dim objMail As MailItem
    Dim objMailDocument As Word.Document
    Dim objHyperlink As Word.Hyperlink
    Dim objDictionary As Object
    Dim i As Integer
    Dim varHyperlinks As Variant
    Dim varHyperlink As Variant
    Dim objInternetExplorer As Object
 
    'Get the source email
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    Set objMailDocument = objMail.GetInspector.WordEditor
    For Each objHyperlink In objMailDocument.Hyperlinks
        If InStr(1, objHyperlink.Address, "www.datanumen.com") > 0 Then
           'Add Hyperlinks to Dictionary
           If objDictionary.Exists(objHyperlink.Address) = False Then
              objDictionary.Add objHyperlink.Address, 1
           End If
        End If
    Next
 
    'Batch Open Hyperlinks on different tabs in same Internet Explorer window
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varHyperlinks = objDictionary.Keys
    For i = LBound(varHyperlinks) To UBound(varHyperlinks)
        varHyperlink = varHyperlinks(i)
 
        If i = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varHyperlink
        Else
           objInternetExplorer.navigate varHyperlink, CLng(2048)
        End If
    Next
End Sub

4. Ensuite, ajoutez cette macro à la barre d'outils ou au ruban d'accès rapide.
5. Enfin, suivez les étapes suivantes pour essayer.

• Tout d'abord, sélectionnez ou ouvrez un e-mail Outlook.
• Ensuite, cliquez sur le bouton macro.
• Immédiatement, les hyperliens avec le domaine prédéfini dans l'e-mail seront ouverts par lots dans Internet Explorer, comme illustré dans l'image suivante :

Débarrassez-vous de la corruption irritante d'Outlook

Bien qu'Outlook soit sensible aux erreurs et à la corruption, en fait, tant que vous surveillez tous les risques, vous pouvez y échapper facilement. Par exemple, vous devez effectuer régulièrement des sauvegardes de données pour Outlook. De plus, vous devez faire attention aux e-mails suspects qui peuvent contenir des virus. Enfin et surtout, vous feriez mieux de préparer un Réparation Outlook utilitaire, comme DataNumen Outlook Repair. Il est capable de vous aider en cas de corruption d'Outlook.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris corrompu SQL Server et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com