Comment marquer automatiquement les rendez-vous du week-end comme privés dans Outlook

Formeost utilisateurs, les rendez-vous programmés le week-end sont généralement privés. Par conséquent, ils souhaitent qu'Outlook marque et affiche automatiquement ces rendez-vous comme privés. Dans cet article, nous allons réaliser cela avec un peu de script.

Afin de distinguer plus facilement les rendez-vous professionnels des rendez-vous privés, Outlook permet aux utilisateurs de marquer les rendez-vous comme privés. De cette façon, vous trouverez qu'il est assez pratique et facile d'imprimer un calendrier sans rendez-vous privés. Dans cette situation, vous souhaiterez peut-être que votre Outlook reconnaisse automatiquement et marque des rendez-vous spécifiques comme privés. Par exemple, généralement, les rendez-vous du week-end sont privés, vous souhaitez donc laisser Outlook les marquer automatiquement comme privés. Par la suite, nous vous guiderons pour y parvenir.

Marquer automatiquement les rendez-vous du week-end comme privés

1. Dans un premier temps, lancez l'éditeur Outlook VBA selon "Comment exécuter le code VBA dans votre Outlook" .
2. Ensuite, dans la fenêtre "Microsoft Visual Basic pour Applications", placez le code suivant dans le projet "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olAppointment Then
       Set objAppointment = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    Call MarkWeedendAppointmentPrivate(objAppointment)
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    If Name = "Start" Or Name = "End" Then
       Call MarkWeedendAppointmentPrivate(objAppointment)
    End If
End Sub

Private Sub MarkWeedendAppointmentPrivate(ByVal objAppointment As Outlook.AppointmentItem)
    Dim dStartDate As Date
 
    dStartDate = Format(objAppointment.Start, "Short Date")
 
    'If the appointment start falls on weekend
    Select Case Weekday(dStartDate)
           Case 7, 1
                'Mark it private
                objAppointment.Sensitivity = olPrivate
    End Select
End Sub

3. Après cela, restart Outlook pour activer la macro.
4. À partir de maintenant, chaque fois que vous créez un nouveau rendez-vous ou modifiez un rendez-vous existant en week-end, Outlook le marque automatiquement comme privé.

Résoudre les problèmes Outlook ennuyeux

Il est possible que vous ayez rencontré des problèmes lors de l'utilisation d'Outlook, tels qu'un blocage inattendu des applications, des messages d'erreur contextuels, etc. En les souffrant, vous seriez inquiet. Calmez vous s'il vous plait! La panique ne servira à rien, mais aggravera le cas. En premier lieu, vous pouvez vérifier si vous pouvez accéder au fichier PST comme d'habitude. Si tel est le cas, vous devez réparer le fichier PST, ce qui peut être accompli via le outil de réparation de boîte de réception ou un outil externe plus puissant, comme DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris réparation mdf et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com