Comment supprimer par lots toutes les adresses e-mail avec un domaine spécifique de vos contacts Outlook

Il peut arriver que vous souhaitiez supprimer de vos contacts toutes les adresses e-mail d'un domaine spécifique. Dans ce cas, vous n'avez certainement pas envie de les supprimer une par une. C'est pourquoi cet article vous propose une méthode bien plus efficace.

Par exemple, une entreprise change de nom. Pendant ce temps, le domaine de l'entreprise est également modifié. Cependant, dans Outlook, vous avez stocké de nombreux contacts dans cette société, dont les adresses e-mail appartiennent à l'ancien domaine. Bien entendu, ces adresses e-mail ne sont plus valides. Par conséquent, dans ces circonstances, si vous souhaitez supprimer ces adresses e-mail en une seule fois, vous pouvez utiliser la méthode suivante.

Supprimer par lots toutes les adresses e-mail avec un domaine spécifique des contacts

1. Pour commencer, accédez à l'éditeur VBA d'Outlook par le raccourci clavier « Alt + F11 ».
2. Ensuite, dans la nouvelle fenêtre, placez le code VBA suivant dans un module vide.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Après cela, placez le curseur dans la sous-routine "BatchRemoveAllEmailAddressesInSpecificDomain".
4. Enfin, cliquez sur la touche "F5" pour déclencher cette macro.
5. Ensuite, entrez le domaine spécifique dans la boîte de dialogue contextuelle.
6. Après avoir cliqué sur "OK", la macro s'exécutera.
7. Une fois terminé, vous recevrez un message sur les résultats.
8. Maintenant, vous pouvez vérifier les contacts. Toutes les adresses e-mail avec le domaine spécifique doivent avoir disparu.

Conservez votre fichier Outlook

Avec de plus en plus de risques entourant votre Outlook, il est de plus en plus difficile de protéger vos précieuses données Outlook. Par exemple, non seulement vous devez persister dans les sauvegardes de données régulières, mais vous devez également faire attention à vos opérations. Il n'est pas sage de se fier facilement aux e-mails d'expéditeurs inconnus. Sinon, s'il contient un virus, votre fichier Outlook sera infecté. À ce moment-là, vous devez essayer Réparation Outlook via un outil de correction remarquable, tel que DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris récupérer Sql Server et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com