Comment exporter par lots plusieurs e-mails Outlook dans un document Word via VBA

Si vous souhaitez exporter par lots plusieurs e-mails Outlook dans un seul document Word, vous pouvez utiliser le code VBA présenté dans cet article. Il peut vous aider à accomplir cette tâche en quelques secondes.

J'ai déjà présenté comment convertir un e-mail Outlook en un document Word dans mon article précédent - "2 méthodes efficaces pour convertir un e-mail Outlook en document Word”. Cependant, les 2 moyens mentionnés dans ce post sera impuissant dans le cas où vous souhaitez exporter par lots de nombreux e-mails dans un seul document Word. Par conséquent, ici, nous allons vous apprendre une autre manière. Maintenant, lisez la suite pour l'obtenir en détail.

Exportation par lots de plusieurs e-mails Outlook dans un seul document Word

1. À start avec, lancez votre programme Outlook.
2. Ensuite, après être entré dans la fenêtre principale d'Outlook, vous devez appuyer sur les touches "Alt + F11".
3. Ensuite, vous aurez accès à l'éditeur Outlook VBA, dans lequel vous devez ouvrir un module vide.
4. Ensuite, copiez le code VBA ci-dessous dans la fenêtre de module ouverte.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Après cela, vous feriez mieux d'ajouter ce nouveau projet VBA à la barre d'outils ou au ruban d'accès rapide.
6. En fin de compte, vous pouvez essayer.

• En premier lieu, sélectionnez plusieurs e-mails Outlook.
• Ensuite, localisez et cliquez sur le bouton macro nouvellement ajouté.
• Une fois que vous êtes invité à "Terminer", vous pouvez accéder au dossier local prédéfini pour trouver un nouveau document Word.
• Ouvrez ce document, dans lequel vous pouvez voir que tous les e-mails sélectionnés ont été exportés.

Gardez un puissant outil de récupération à proximité

Indépendamment de nombreuses fonctions, Outlook ne peut toujours pas être à l'abri des erreurs. Si vous avez l'habitude de laisser les erreurs seules, avec leur accumulation, le crash d'Outlook se produira définitivement. À ce stade, il est essentiel de recourir à un outil de récupération puissant et efficace, comme DataNumen Outlook Repair. Il est bien versé dans Correction PST. Tant que vous l'utiliserez, vous n'aurez plus à vous soucier de la perte de données Outlook.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris mdf corrompu et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com