Comment exporter par lots les photos et les informations de plusieurs contacts avec Outlook VBA

Si vous souhaitez extraire les photos des contacts et leurs informations principales dans un dossier sur votre disque local par lots, vous devez utiliser Outlook VBA. Cet article vous apprendra comment y parvenir en détail.

Outlook vous permet d'exporter les informations de contact via la fonction "Importer et exporter". Vous pouvez aller dans "Fichier" > "Imprimer" > "Importer" > "Exporter vers un fichier".

Cependant, cette fonctionnalité ne vous permet pas d'exporter les photos de contact. Ainsi, si vous souhaitez extraire à la fois les informations de contact et les photos, vous devez recourir à Outlook VBA. Voici les codes VBA et les étapes qui peuvent enregistrer les photos de contact dans un dossier local spécifié et extraire les informations de contact dans un fichier texte.

Exporter par lots les photos et informations de plusieurs contacts

1. En premier lieu, lancez Outlook et appuyez sur les touches "Alt + F11".
2. Ensuite, vous aurez accès à l'éditeur VBA. Vous devez maintenant ouvrir un module qui n'est pas utilisé ou créer un nouveau module par "Insérer"> "Module".
3. Ensuite, copiez et collez les codes VBA suivants dans le nouveau module.

Sub BatchExportContactPhotosandInformation()
    Dim objContacts As Outlook.Items
    Dim objContact As ContactItem
    Dim strContactInfo As String
    Dim objFileSystem As Object
    Dim objTextfile As Object
    Dim objAttachments As Attachments
    Dim objAttachment As Attachment
    Dim strName As String
 
    'Specify the contacts in the default contact folder
    Set objContacts = Outlook.Application.Session.GetDefaultFolder(olFolderContacts).Items
 
    For Each objContact In objContacts
        If TypeOf objContact Is ContactItem Then
           'Get the contact's primary informtaion
           strContactInfo = "Name: " & objContact.FullName & vbCrLf & "Email: " & objContact.Email1Address & vbCrLf & "Company: " & objContact.Companies & vbCrLf & "Job Title: " & objContact.JobTitle & vbCrLf & "Business Address: " & objContact.BusinessAddress & vbCrLf & "Business Phone: " & objContact.BusinessTelephoneNumber
           'Create a Text file
           Set objFileSystem = CreateObject("Scripting.FileSystemObject")
           'You can change the folder path as per your needs
           Set objTextfile = objFileSystem.CreateTextFile("C:\Outlook Contacts\" & objContact.FullName & ".txt", True)
           objTextfile.WriteLine (strContactInfo)
 
           'Save the contact photos
           If objContact.Attachments.Count > 0 Then
              Set objAttachments = objContact.Attachments
              For Each objAttachment In objAttachments
                  If InStr(LCase(objAttachment.filename), "contactpicture.jpg") > 0 Then
                     strName = objContact.FullName & ".jpg"
                     objAttachment.SaveAsFile ("C:\Outlook Contacts\" & strName)
                  End If
              Next
           End If
       End If
    Next
End Sub

À noter: Les codes ci-dessus exporteront les photos et les informations des contacts dans votre dossier de contacts par défaut. Vous pouvez modifier les contacts spécifiés.

• Si vous souhaitez exporter les photos et les informations des contacts dans le dossier actuellement ouvert, vous devez remplacer « Set objContacts = ….. » par :

Set objContacts = Outlook.Application.ActiveExplorer.CurrentFolder.Items

• Si vous espérez uniquement exporter les photos et les informations des contacts sélectionnés, vous pouvez utiliser les lignes suivantes :

Dim objSelection as Selection
Set objSelection = Outlook.Application.ActiveExplorer.Selection
For each objContact in objSelection

4. Après cela, vous pouvez fermer l'éditeur VBA et ajouter le nouveau projet à la barre d'outils d'accès rapide comme d'habitude.
5. Enfin, vous pouvez cliquer sur le bouton macro dans la barre d'outils d'accès rapide. Immédiatement, les photos et informations de contact seront exportées vers le dossier spécifié sur le disque local.

Vous pouvez ouvrir un fichier texte, dans lequel les informations principales seront répertoriées, comme la capture d'écran suivante :

Gérer la corruption inattendue d'Outlook

C'est un fait incontestable qu'Outlook est vulnérable. Par conséquent, si vous souffrez de corruption d'Outlook, vous devez d'abord vous calmer. Ensuite, vous pouvez continuer à réparer le e-mail Outlook PST corrompu. Vous pouvez utiliser l'outil de réparation de la boîte de réception pour essayer. En cas d'échec, vous n'avez d'autre choix que d'utiliser un outil beaucoup plus puissant, tel que DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris réparer la base de données SQL mdf endommagée et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com