Comment définir automatiquement une heure de rappel différente pour les réunions Outlook dans différentes catégories de couleurs

Si vous classez les réunions Outlook par catégories de couleurs et que vous souhaitez définir une heure de rappel différente pour les réunions dans différentes catégories de couleurs, vous pouvez vous référer à cet article. Ici, nous allons vous apprendre à le réaliser avec Outlook VBA.

Par exemple, vous répartissez vos réunions en deux groupes : les réunions hors site (lieu trop éloigné) et les réunions sur site (lieu proche). Vous souhaitez qu’Outlook programme automatiquement un rappel une heure avant le début des réunions hors site et 15 minutes avant le début des réunions sur site. Pour répondre à ce besoin, nous vous proposons une méthode simple.

Définir automatiquement un rappel différent pour les réunions dans différentes catégories de couleurs

1. Pour commencer, lancez votre application Outlook.
2. Ensuite, appuyez sur les touches "Alt + F11" pour accéder à la fenêtre de l'éditeur VBA.
3. Ensuite, dans la fenêtre suivante, copiez et collez le code VBA ci-dessous dans le projet "ThisOutlookSession".

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Ensuite, vous devrez cliquer sur la sous-routine « Application_Startup » et appuyer sur la touche « F5 » pour exécuter cette macro.
5. Depuis lors, chaque fois qu'une nouvelle réunion est ajoutée au calendrier par défaut ou que vous modifiez une réunion existante, Outlook vérifie automatiquement les catégories de la réunion et définit automatiquement l'heure de rappel différente.

Éliminer les erreurs Outlook

Outlook peut rencontrer divers problèmes de temps à autre. Il est donc essentiel que les utilisateurs apprennent à les résoudre. Pour commencer, il est conseillé d'effectuer régulièrement des sauvegardes de vos données Outlook. De plus, si votre budget le permet, il est recommandé de conserver un système de sauvegarde performant. Réparation Outlook outil à proximité, tel que DataNumen Outlook Repair. Il peut analyser votre fichier PST pour comprendre les problèmes d'Outlook, puis les résoudre facilement.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris récupération SQL et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com