Comment appliquer automatiquement les catégories d'un e-mail à toutes ses réponses et transferts dans Outlook

Solutions Outlook 29 septembre

Lorsque vous répondez ou transférez un e-mail, vous souhaiterez peut-être appliquer les mêmes catégories. Dans cet article, nous allons vous apprendre à réaliser cela avec du code VBA.

Si vous avez l'habitude d'attribuer les mêmes catégories de couleurs d'e-mail d'origine à toutes ses réponses et transferts, pourquoi ne laissez-vous pas Outlook le faire automatiquement ? Même si Outlook ne fournit pas une telle fonctionnalité directe, vous pouvez toujours l'obtenir à l'aide du code VBA. Dans ce qui suit, nous vous exposerons les étapes détaillées et le code.

Appliquer automatiquement les catégories d'un e-mail à toutes ses réponses et transferts

Au tout début, lancez l'application Outlook.
Ensuite, appuyez sur les touches "Alt + F11" pour exécuter l'éditeur Outlook VBA.
Ensuite, copiez le code VBA suivant dans le projet "ThisOutlookSession".

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

Après cela, restart votre Outlook pour activer ce projet.
Depuis lors, vous pouvez l'essayer en suivant les étapes ci-dessous.

Tout d'abord, sélectionnez un e-mail et cliquez sur le bouton "Transférer".
Ensuite, un e-mail de transfert s'affichera, dans lequel vous pourrez passer à l'onglet "Options" et appuyer sur l'icône d'extension dans le coin inférieur droit du groupe "Plus d'options".
Ensuite, dans la boîte de dialogue contextuelle "Propriétés", vous pouvez voir que cet e-mail est attribué aux mêmes catégories de couleurs que l'e-mail d'origine.

Réparer le fichier Outlook endommagé

Étant donné qu'Outlook est vulnérable, vous devez prendre de nombreuses mesures pour éviter la perte de données Outlook. Par exemple, vous devez effectuer des sauvegardes périodiques des données. De plus, il est nécessaire que vous vous méfiiez des e-mails inconnus, y compris les liens intégrés ou les pièces jointes. Enfin et surtout, vous devriez vous procurer un outil de réparation externe de pointe, comme DataNumen Outlook Repair. Il est capable de vous aider à récupérer un maximum de données de Outlook corrompu fichier.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris SQL Server fixer et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com