3 méthodes pour importer des e-mails d'un dossier Windows vers votre Outlook

Solutions Outlook 29 septembre

Vous avez peut-être enregistré plusieurs e-mails Outlook dans votre dossier Windows. Maintenant, si vous souhaitez les réimporter dans un dossier Outlook, comment pouvez-vous le faire ? Cet article vous apprendra 3 façons.

Comme nous le savons tous, Outlook fournit une option intégrée - "Enregistrer sous", par laquelle vous pouvez enregistrer les e-mails dans le dossier Windows. Cependant, aucune fonctionnalité ne vous permet de rajouter les e-mails exportés dans le dossier Outlook. Par conséquent, si vous souhaitez réimporter les e-mails Outlook dans Outlook, comment pouvez-vous le réaliser ? Dans ce qui suit, nous vous apprendrons 3 méthodes. Vous pouvez en choisir selon vos préférences.

Méthode 1 : glisser-déposer pour importer

Au tout début, vous devez accéder au dossier Windows source qui stocke les e-mails Outlook à importer dans Outlook.
Ensuite, lancez votre application Outlook.
Ouvrez ensuite le dossier Outlook dans lequel vous souhaitez importer les e-mails.
Par la suite, vous devez réduire à la fois la fenêtre du dossier Windows et la fenêtre Outlook jusqu'à ce que vous puissiez les afficher entre-temps.
Après cela, dans le dossier Windows, vous pouvez sélectionner l'un des e-mails Outlook, puis appuyer sur "Ctrl + A" pour les sélectionner tous.
Plus tard, vous pouvez faire glisser et déposer les e-mails sélectionnés dans le dossier Outlook visible, comme la capture d'écran suivante :
Enfin, vous verrez que tous les e-mails Outlook ont été importés du dossier Windows vers le dossier Outlook, comme illustré ci-dessous :

Méthode 2: utilisez "CreateItemFromTemplate" dans VBA

Pour commencer, dans la fenêtre principale d'Outlook, appuyez sur les touches « Alt + F11 ».
Ensuite, vous aurez accès à la fenêtre de l'éditeur Outlook VBA.
Copiez ensuite le code VBA suivant dans un module vide.

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

Vous pouvez ensuite appuyer sur la touche F5 dans la fenêtre du module actuel pour démarrer la macro.
Après cela, vous devez accéder au dossier Windows source dans la boîte de dialogue contextuelle.
Enfin, après avoir sélectionné le dossier source, tous les éléments Outlook de ce dossier seront importés dans le dossier Outlook prédéfini.
Remarque : de cette manière, les e-mails importés sont tous de nouveaux e-mails frais, que vous pouvez composer à volonté, comme la capture d'écran suivante :

Méthode 3 : Utiliser "OpenSharedItem" dans VBA

Comme la méthode 2, copiez les codes VBA suivants dans un autre module.

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

Exécutez ensuite cette macro en appuyant sur la touche "F5".
Sélectionnez ensuite le dossier source.
Finalement, tous les e-mails seront importés comme l'image ci-dessous :

Comparaisons

Méthodologie	Avantages	Désavantages
Méthode 1	Il est plus facile d'être accepté pour ceux qui ne sont pas familiers avec VBA.	Cela vous oblige à réduire les deux fenêtres jusqu'à ce que vous puissiez voir les deux.
Méthode 2	Vous pouvez utiliser les e-mails importés comme de nouveaux e-mails frais, que vous pouvez composer et envoyer à volonté.	S'il existe d'autres éléments Outlook enregistrés au format ".msg" dans le dossier Windows, tels que des contacts ou des tâches, cette méthode les importera également.
Méthode 3	Il peut reconnaître précisément les e-mails Outlook et échapper à d'autres éléments Outlook.	Par ce moyen, vous ne pouvez pas composer et envoyer les e-mails importés aussi facilement qu'avec la méthode 2.

Moyens de bloquer la corruption des données PST

Comme nous le savons tous, Outlook est préinstallé avec un outil intégré - ScanpstLa plupart du temps, il est capable de résoudre les petits problèmes. Cependant, si les problèmes sont extrêmement graves, l'outil intégré risque de ne pas suffire. Il est donc préférable d'utiliser un outil plus puissant, tel que… DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris SQL Server la corruption et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com