2 façons rapides d'exporter la liste de tous les e-mails Outlook marqués vers Excel

Si vous souhaitez exporter la liste de tous les e-mails marqués de votre boîte aux lettres Outlook vers Excel, vous pouvez utiliser l'une des 2 méthodes partagées dans cet article.

Par exemple, afin de traiter tous les e-mails signalés plus rapidement ou de les partager avec quelqu'un d'autre, vous pouvez espérer les exporter vers une feuille de calcul Excel. Ici, nous présenterons 2 approches pour le réaliser. Le premier utilise la fonction standard "Importer et exporter" après avoir trouvé des e-mails marqués. Pour être honnête, c'est un peu fastidieux. Ainsi, dans ce dernier, nous vous apprendrons une méthode plus pratique qui applique VBA.

Méthode 1 : Exporter manuellement tous les e-mails signalés trouvés

1. Tout d'abord, cliquez dans le champ de recherche au-dessus de la liste de diffusion.
2. Ensuite, cliquez sur "Tous les éléments de messagerie" dans le groupe "Portée" de l'onglet "Rechercher".
3. Ensuite, cliquez sur le bouton "Marqué" dans le groupe "Définir".
4. Après tous les e-mails marqués affichés dans la liste, sélectionnez un e-mail et appuyez sur "Ctrl + A" pour les sélectionner tous.
5. Ensuite, appuyez sur les raccourcis clavier "Ctrl + Maj + V".
6. Dans la nouvelle boîte de dialogue, créez un nouveau dossier sous le fichier Outlook.
7. Plus tard, sélectionnez le nouveau dossier créé et cliquez sur "OK", ce qui déplacera tous les e-mails marqués trouvés vers le nouveau dossier.
8. Ensuite, cliquez sur "Fichier" > "Ouvrir" > "Importer",
9. Dans la boîte de dialogue contextuelle, choisissez « Exporter vers un fichier » > « Suivant » > « Microsoft Excel 97-2003 » > « Suivant ».
10. Dans le nouvel écran, sélectionnez le bon dossier et cliquez sur "Suivant".
11. Ensuite, suivez les assistants pour terminer "Exporter".
12. Vous obtiendrez un nouveau fichier Excel, illustré par la capture d'écran suivante.

Méthode 2 : Exporter la liste de tous les e-mails marqués via VBA

1. Dans Outlook, appuyez sur "Alt + F11" pour déclencher l'éditeur VBA.
2. Ensuite, activez "MS Excel Object" conformément à "Comment ajouter une bibliothèque d'objetsrary Référence dans VBA" .
3. Ensuite, copiez le code VBA ci-dessous dans un module.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Enfin, placez le curseur dans la sous-routine "ExportAllFlaggedEmailsToExcel" et appuyez sur la touche "F5".
5. Ensuite, sélectionnez un fichier Outlook dans la nouvelle boîte de dialogue.
6. Lorsque vous obtenez l'invite "Terminé", vous obtenez également un nouveau fichier Excel, comme l'image ci-dessous.

Protégez votre Outlook de la corruption

Outlook est sujet aux erreurs et à la corruption, c'est donc une tâche très ardue pour nous de protéger nos données Outlook. Sans aucun doute, le most manière efficace et pratique est de faire des sauvegardes de données régulières pour Outlook. En plus de cela, il nous est également nécessaire de disposer d'un outil de correction Outlook puissant et fiable, tel que DataNumen Outlook Repair. Cela vous sera utile si outil de réparation de boîte de réception ne fait aucun effet.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris fixer SQL Server et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com