2 méthodes pour supprimer par lots tous les contacts sans adresse e-mail dans votre Outlook

Si vous constatez que certains contacts n'ont pas d'adresse e-mail dans votre Outlook, vous pouvez supprimer ces contacts en traitant chaque dossier de contacts. Cet article vous présente deux méthodes.

Vous avez peut-être de nombreux contacts dans votre Outlook et certains d'entre eux n'ont pas d'adresse e-mail. Si vous pensez qu'ils ne sont plus utiles, vous devez espérer supprimer tous les contacts sans adresse email. De manière standard, vous pouvez utiliser "Recherche instantanée" pour les trouver, puis les supprimer manuellement, comme la méthode 1 suivante. Pourtant, c'est un peu fastidieux. Par conséquent, dans la méthode 2, nous vous apprendrons une autre méthode plus efficace.

Méthode 1 : Supprimer manuellement après avoir trouvé des contacts sans adresse e-mail

1. Pour commencer, appuyez sur les touches « Ctrl + 3 » pour accéder au volet « Contacts ».
2. Cliquez ensuite dans le champ de recherche.
3. Ensuite, dans le ruban "Rechercher" qui apparaît, cliquez sur "Tous les éléments de contact".
4. Ensuite, cliquez sur "A une adresse"> "A une adresse e-mail".
5. Après cela, le critère "NOT emailaddresses :=[]" sera ajouté dans le champ de recherche. Vous devez supprimer le « NON ».
6. Par la suite, tous les contacts sans adresse e-mail seront listés.
7. Maintenant, vous devez sélectionner manuellement les contacts dans les résultats de la recherche, car vos groupes de contacts doivent également figurer dans la liste.
8. Enfin, appuyez sur la touche "Suppr" pour supprimer tous les contacts sélectionnés.

Méthode 2 : supprimer par lots tous les contacts sans adresse e-mail avec VBA

1. Dans un premier temps, appuyez sur "Alt + F11" pour lancer l'éditeur VBA dans Outlook.
2. Dans le nouvel écran, copiez le code VBA suivant dans un module.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Plus tard, cliquez sur la sous-routine "BatchDeleteAllContactsWithoutEmailAddress".
4. Enfin, appuyez sur "F5" pour déclencher cette macro.
5. Une fois terminé, vous recevrez un message sur les résultats, comme l'image ci-dessous.
6. Tous les contacts sans adresse e-mail ont été déplacés vers le dossier "Éléments supprimés".

Tenez-vous loin de tous les risques potentiels

Outlook peut être endommagé en raison de divers facteurs, tels que des virus, des erreurs de l'utilisateur, des défaillances logicielles ainsi que des défaillances matérielles. Vous devez être réticent à subir des dommages Outlook, vous devez donc garder tous ces risques potentiels à distance. Par exemple, vous devez installer un logiciel antivirus puissant sur votre PC. De plus, vous devez sauvegarder régulièrement vos données Outlook. Enfin, vous feriez mieux de préparer un outil de réparation robuste et fiable, tel que DataNumen Outlook Repair. Il peut réparer votre PST corrompu déposer en toute simplicité.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris SQL Server la corruption et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com