Kuinka poistaa nopeasti päällekkäiset Outlook-kohteet kansiosta VBA: n kautta

Jos haluat poistaa päällekkäiset kohteet Outlookista, niiden etsiminen ja poistaminen yksi kerrallaan voi olla melko hankalaa. Tässä artikkelissa opit, kuinka se tehdään nopeasti Outlook VBA:lla.

Edellisessä artikkelissani - “Kuinka nopeasti löytää ja poistaa päällekkäisiä sähköpostiviestejä Outlookissa”, voit opetella tempun päällekkäisten sähköpostien etsimiseen ja poistamiseen, joka lajittelee sähköpostit ensin aiheen, sitten vastaanoton ajan ja sitten liitteiden mukaan löytääkseen päällekkäiset kohteet ja lopuksi valitse kopiot ja paina "Poista"-näppäintä. Vaikka tämä menetelmä on näennäisesti hieman kätevämpi, se on paljon hankalampi verrattuna Outlook VBA:n käyttöön. Seuraavien VBA-koodien avulla voit nopeasti poistaa päällekkäiset kohteet yksinkertaisesti yhdellä napsautuksella, sähköpostista, tehtävistä, yhteystiedoista tai tapaamisista riippumatta. Lue nyt saadaksesi koodit yksityiskohtaisesti.

Poista päällekkäiset Outlook-kohteet kansiosta

1. Aloita käynnistämällä Outlook-ohjelmasi.
2. Paina sitten ”Alt + F11” -näppäimiä.
3. Seuraavassa VBA-editoriikkunassa kaksoisnapsauta avataksesi moduulin, joka on käytössä, tai lisää suoraan uusi moduuli valitsemalla "Lisää" > "Moduuli".
4. Seuraavaksi kopioi ja liitä seuraavat VBA-koodit moduuliin.

Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

5. Sen jälkeen allekirjoita tämä makro digitaalisesti ja muuta Outlook-makrosi suojaustaso alhaiseksi.
6. Myöhemmin voit suorittaa tämän uuden VBA-projektin. Napsauta suoraan työkalupalkin "Suorita" -kuvaketta.
7. Tämän jälkeen sinun on valittava kansio, josta haluat poistaa päällekkäiset kohteet.
8. Lopuksi valitun kansion päällekkäiset kohteet poistetaan heti.

Suojaa haavoittuvia PST-tietoja

Koska PST-tiedosto on alttiina korruptiolle, sinun tulee käyttää paljon vaivaa PST-tiedoston suojaamiseen. Sinun tulisi esimerkiksi estää Outlookin sulkeminen väärin. Lisäksi sinun on valmisteltava vankka Outlook-korjaus työkalu, kuten DataNumen Outlook Repair joka voi pelastaa PST:si ajoissa.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien toipua SQL Server ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com